Try something like this; it out performs most other methods I've seen. You might want to try adjusting BUFSIZE. 64k works best on my system, but your's may differ.

Updated: Corrected handling of partial buffer.

#! perl -slw
use strict;
use constant BUFSIZE => 65536;

chomp( my $searchTerm = $ARGV[ 0 ] // 'five' );

open BIGFILE, '+<', 'theFile' or die $!;

my $readPos = my $writePos = 0;
my $buffer = '';
while( <BIGFILE> ) {
    $readPos = tell BIGFILE;
    if( ! m[^\Q$searchTerm\E] ) {
        $buffer .= $_;
        if( length( $buffer ) > BUFSIZE ) {
            sysseek BIGFILE, $writePos, 0;
            syswrite BIGFILE, $buffer;
            $writePos = sysseek BIGFILE, 0, 1;
            $buffer = '';
            seek BIGFILE, $readPos, 0;
        }
    }
}

if( length( $buffer ) ){
    sysseek BIGFILE, $writePos, 0;
    syswrite BIGFILE, $buffer;
    $writePos = sysseek BIGFILE, 0, 1;
}

truncate BIGFILE, $writePos;

close BIGFILE;
[download]

Do you have long, and different rows:

searchme1|data1|more|auxiliary|data|that|is|very|long
searchmetoo|and|some|parametric|data|that|can|be|discarded
thirdsearch|and|the|file|looks|like|this?
[download]

Where the first item after a separator "|" is the search term you need to capture and ignore the rest?

And somehow, this does not work or takes too long due to the long lines:

perl -ne 'print unless /search_this_text/' lines.txt
[download]

Final question: What is the "modification" you need on that file? Mark a certain field, make the line start with #, remove the full line from the big file? (i.e. Will you require the same space, or will filesize change after such edit?)