my $q_file = "tmp.txt";
my $n = 10;

my @ques = get_questions($q_file, $n);
print for @ques;

sub get_questions {
 local $/="===\n";
 local $.; # Is this necessary?
 local @ARGV = (shift);
 # If you want 'open ... or die' behavior
 local $SIG{__WARN__} = sub { die shift };

 my $num = shift;
 my @questions;
 while (<>) {
  push(@questions, $_), next if $. <= $num;
  my $i = rand($.);
  $questions[$i] = $_ if $i < $num;
 }
 @questions;
}
[download]

I like this solution best because it does something honestly new and unusual.

However there is one caveat. While it does indeed avoid reading the file into memory, and the actual questions chosen are randomized, the first 10 questions in the list will always appear "in position" if they appear. For perfectly random questions, therefore, it would be best to throw in a shuffle at the end.

Or you can just shuffle them from the start:

my $num = shift;
my @init = (0..$num-1);
my @questions;
while (<>) {
  $questions[splice @init, rand(@init), 1] = $_, next if $. <= $num;
  my $i = rand($.);
  $questions[$i] = $_ if $i < $num;
}
[download]

my $file = do { local $/; <FILE> }; # slurp
my @questions = $file =~ /(^question.*\n(?:(?!question).*\n)*)/gm;
for (1..10) { # 10 questions at random
  my ($one) = splice @questions, rand @questions, 1;
  my %param = $one =~ /^(\w+)=(.*)/gm;
  print $param{question}, "\n";
  print "$_: ", $param{"option$_"}, "\n" for 1..4;
  ... etc ...
}
[download]

-- Randal L. Schwartz, Perl hacker

use POSIX qw/floor/;

local $/= '===';

my @allquestions = <QUESTIONS>;
my @questions;

for (1..$maxcount){
  my $idx = floor rand @allquestions;  
  push @questions, splice @allquestions, $idx, 1;
}
return @questions;
[download]

Than you'll have to solve your delimiter problem. Dunno what it is, run some checks on that. (We're discussing that in CB right now) And, of course, use strict and warnings.

Jeroen
"We are not alone"(FZ)

Update I added the local thing... too important to miss out... read Why or why not? - local undef $/ and Use strict warnings and diagnostics or die eg.

Update 2 merlyn made me realize (again) that you don't need to floor the stuff:

local $/= '===';

my @allquestions = <QUESTIONS>;
my @questions;

push @questions, splice @allquestions, rand @allquestions, 1 for (1..$
+maxcount)

return @questions;
[download]

local $,=$/."****".$/;
local $\=$/;

sub rand_questions {
    my $total=shift;

    local $/ = "===\n";   # set our delimiter
    my @data=<DATA>;
    #fisher yates shuffle
    my $i;
    for ($i = @data; --$i; ) {
         my $j = int rand ($i+1);
        # next if $i == $j; # See tillys reply
        @data[$i,$j] = @data[$j,$i];
    }

    my @questions=@data[0..$total-1];
    return @questions;
}

print rand_questions(2);



__DATA__
question=When driving towards a bright setting sun, glare can be reduc
+ed by
option1=closing one eye
option2=dipping in the interior mirror
option3=wearing dark glasses
option4=looking sideways
answer=4
answertext=Dark glasses are often used as a fashion item but they do h
+ave their practical uses. Low sun in the early morning or evening can
+ dazzle and distract. Lessen the risk by reducing the glare. Wear dar
+k glasses if they help you to see better.
category1=car
category2=vechicle handling
===
question=2When driving towards a bright setting sun, glare can be redu
+ced by
option1=closing one eye
option2=dipping in the interior mirror
option3=wearing dark glasses
option4=looking sideways
answer=4
answertext=Dark glasses are often used as a fashion item but they do h
+ave their practical uses. Low sun in the early morning or evening can
+ dazzle and distract. Lessen the risk by reducing the glare. Wear dar
+k glasses if they help you to see better.
category1=car
category2=vechicle handling
===
question=3When driving towards a bright setting sun, glare can be redu
+ced by
option1=closing one eye
option2=dipping in the interior mirror
option3=wearing dark glasses
option4=looking sideways
answer=4
answertext=Dark glasses are often used as a fashion item but they do h
+ave their practical uses. Low sun in the early morning or evening can
+ dazzle and distract. Lessen the risk by reducing the glare. Wear dar
+k glasses if they help you to see better.
category1=car
category2=vechicle handling
===
[download]

Yves
--
You are not ready to use symrefs unless you already know why they are bad. -- tadmc (CLPM)

As noted in Fisher-Yates Shuffle, the check for whether the two elements are equal is inefficient. The cost of adding the check scales linearly with the number of elements. The number of saved swaps scales logarithmically.

The only time it is important to have the check is when your swap will run into trouble if the two elements are the same. This is true in C if you are using xor to perform the swap in place. It is not true in Perl. Therefore in Perl it is both faster and clearer to drop the check.

while (<QUESTIONS>) {
[download]

 
for (@questions) {
[download]

sub get_std_test {
  die +(caller(0))[3].' cannot be called in void context'
    if not defined wantarray;

  local $/;  # set our delimiter to nothing, slurp file

  my %config = mcas::get_config(); # returns a hash of all config vars

  my @questions;

  open QUESTIONS, 'questions' or die "Cannot open QUESTIONS file: $!";

  my @questions = split "===\n", <QUESTIONS>;
  close QUESTIONS;

  while(@questions > $config{num_questions_per_test}) {
      splice @questions, int(rand(@questions)), 1;
  }

  die "\$count = $count, < num_questions_per_test config var"
    if (@questions < $config{num_questions_per_test});

  return @questions;
}
[download]

                - Ant
                - Some of my best work - Fish Dinner

Your question selector is broken, even if you arrange for one question per line.

If you (for example) only want 2 questions, then you've now got a 5/6 chance of having selected them. So question 4 will only be tested 1/6 of the time, and then get pushed 1/4 of that: a total selectability of 1/24, not the 1/4 you intended.

if you really want to get all the questions in a single pass through the file, then you need to determine whether to keep the question (using rand), and then push the relevant details into a stack. At the end pop the last N elements off and use them.

That's esentially what the trick in the Cookbook does, but it uses a simple stack, of only one entry (aka a variable ;)

It looks like you are reading in the questions file one line at a time rather than parsing them by the === separator. I would do something more like this:

my @lines = <QUESTIONS>; # The entire file in an array
my @questions = (); # A new array for questions
my $tmp = ""; # A tmp variable to capture stuff in
my $count = 0;
foreach my $line(@lines) {
     if($line =~ /^===$/) {
          push(@questions,$tmp) unless $count == 0;
          $tmp = "";
          next;
     }
     $tmp .= $line;
}
# and then to get the last one
push(@questions,$tmp) if $tmp;
[download]

Then to get your random stuff

my @rand_questions = ();
foreach (0 .. $num_questions_per_test) {
     my $rand = int(rand(scalar(@questions) - 1);
     push(@rand_questions,$questions[$rand]);
}
[download]

That would put all the random questions in the array rand_questions. I'm sure there are ways to make it simpler I tend to code the long way so I can understand it when I look at it 6 months later :) hope that helps.