Re^3: Read Directory and getlines in .csv

Not sure what part you are having trouble with but try this

#!/usr/bin/perl
use strict;
use warnings;
use File::stat;
use Text::CSV_XS;
my $csv = Text::CSV_XS->new(
  { binary => 1, eol => $/ }
);

my $ONE_DAY = 86400;
my $Foutput = "data0426-2.csv";
open my $out, ">", $Foutput or die "$!";

# create array of csv filenames in directory
my $dirname = "Daily_QoS_CPD_link";
unless (-d $dirname) { 
  die "Not able to open $dirname";
}
my @dir = glob "$dirname/*.csv";
   
# parse files modifed in past 24 hours  
foreach my $infile (@dir){
    
  my $age = time()-stat($infile)->mtime;
  if( $age < $ONE_DAY ){  
    open my $FH, "<", $infile or die "Could not open $infile : $!";
    while (my $row = $csv->getline($FH)) {
      if ( $row->[2] =~ /^(DROPPED-10|CALL_START|CALL_END)$/ ) {
        $csv->print($out, $row);
      }
    }
    close $FH;      
  }
}
[download]

poj

Comment on Re^3: Read Directory and getlines in .csv Download Code

Replies are listed 'Best First'.
Re^4: Read Directory and getlines in .csv by Dipepper (Novice) on Apr 27, 2016 at 17:22 UTC
Works beautifully. I think I need to look up a few things to see how/why/what of them like using "glob" and "unless. Whew! Most of the components you have in your code are what I had in mine. I was close, but, alas...no cigar. (sad face) BUT->I'm learning!! Thank you so much for your assistance. I kinda like Perl, its very powerful.	[reply]
Re^5: Read Directory and getlines in .csv by Laurent_R (Canon) on Apr 27, 2016 at 20:13 UTC
`glob` does more or less the same thing as opendir /readdir, except that it is more practical: first, it's one line instead or two, second it removes pseudo-directories such as "." and ".." which you usually don't want to explore, and finally it returns a list of files with their path, so that you can open them without having to add the path. `unless` does exactly what the English meaning of the word implies. It is essentially equivalent to `if not`. For example: `my $q = $c / $d unless $d == 0; # avoid division by zero error` [download]	[reply] [d/l] [select]