use strict;
use warnings;
use feature 'say';
my %hash = ( 'a' => 1, 'b' => 2, 'c' => '1', 'd' => 3,
             'e' => '5');
  my (%seen,@dups); 
  while (my($k,$v)=each %hash){
    if ( defined $seen{$v}){
      push @dups,$k;
      $seen{$v} and push @dups,$seen{$v};
      $seen{$v}='';
      next
    }
    $seen{$v}=$k
  }
say for sort @dups;
__OUTPUT__
a
c
[download]

This solution inverts the hash like this:

 k1   v1 k2   v2 k3   v1     v1           v2
(a => 1, b => 2, c => 1) => (1  => [a,c], 2 => [b])
[download]

Then it just becomes a matter of finding those value-keys who point to more than a single original key name.

use strict;
use warnings;

my %hash = (a => 1, b => 2, c => 1, d => 3, e => 5);

my @non_unique = duplicated_values_keys(%hash);

print "$_\n" for @non_unique;

sub duplicated_values_keys {
    my %hash = @_;
    my %inverted;
    push @{$inverted{$hash{$_}}}, $_ for keys %hash;
    return map {@{$inverted{$_}} > 1 ? @{$inverted{$_}} : ()} keys %in
+verted;
}
[download]

Outputs:

a
c
[download]

...in no particular order.

ANOTHER idea is to loop over the values:

for my $val (values %hash){

And detect FIRST which ones you already seen (using %SEEN in a numerical fashion), before looping through the keys and knowing the value, look it up if you seen it already.

Also, write your hash definition like this:

use strict;
use warnings;
my %hash = ( 'a' => 1, 'b' => 2, 'c' => '1', 'd' => 3, 'e' => '5' );
[download]

keys

my %seen;
$seen{$_}++ for values %hash;
my @dups = grep { $seen{ $hash{$_} } > 1 } keys %hash;
print join(',', sort @dups );
[download]