Hello theravadamonk,

It’s simpler if you read in a whole message (four lines: Message Time, Mail From, Mail to, quarantine) at a time, and then search for “jay” in one of the addresses. Here is one approach:

#! perl
use strict;
use warnings;
use Data::Dump;

my @message;

READ_FILE: while (<DATA>)
{
    push @message, $_;

    for (1 .. 3)
    {
        last READ_FILE unless defined(my $line = <DATA>);
        push @message, $line;
    }

    if ($message[1] =~ /<jay@/i ||          # Mail From:
        $message[2] =~ /<jay@/i)            # Mail to:
    {
        print "\n", join('', @message);
    }

    @message = ();
}

__DATA__
Message Time: Feb 3 11:24:54
Mail From: <letter@leemaletter.com>
Mail to: <info@example.com>,<jay@example.com>
quarantine: spam-JF6LBytcy_3D.gz
Message Time: Feb 3 11:25:18
Mail From: <noreply@lankaemarketing40.info>
Mail to: <jay@example.com>
quarantine: spam-uXWM3SJ-nlB0.gz
Message Time: Feb 3 11:25:29
Mail From: <bounce@rhmarketing.info>
Mail to: <sam@example.com>
quarantine: spam-uOG8ycqZrq1s.gz
Message Time: Feb 3 11:25:47
Mail From: <Jay@example.com>
Mail to: <userx@gmail.com>
quarantine: spam-FxfQDEDm-5MW.gz
[download]

Output:

12:51 >perl 1624_SoPW.pl

Message Time: Feb 3 11:24:54
Mail From: <letter@leemaletter.com>
Mail to: <info@example.com>,<jay@example.com>
quarantine: spam-JF6LBytcy_3D.gz

Message Time: Feb 3 11:25:18
Mail From: <noreply@lankaemarketing40.info>
Mail to: <jay@example.com>
quarantine: spam-uXWM3SJ-nlB0.gz

Message Time: Feb 3 11:25:47
Mail From: <Jay@example.com>
Mail to: <userx@gmail.com>
quarantine: spam-FxfQDEDm-5MW.gz

12:51 >
[download]

Notes:

1. Case-insensitive matching is achieved by adding the /i modifier to the regex.
2. The above approach will work only if the 4-line messages are placed contiguously in the data file (no intervening blank lines), with the first message beginning on the first line.

Hope that helps,

Thanks. Works very well. Sorry for the delay in writing. I was very busy. Pls forgive me.

#!/usr/bin/env perl

use strict;
use warnings;

my @message;

while (<DATA>)
{
    push @message, $_;
    if ( /quarantine/ ) {  # this is the last expected line of each me
+ssage
        local $_ = join( "", @message );
        local $\ = "\n";
        print if ( /<jay@/i );
        @message = ();
    }
}
[download]

You can write a one-liner like :

perl -ne 'BEGIN{$/=qq|\n\n|}print if m/jay/s' Your-quarantine-file-nam
+e-here.txt
[download]