It will be easier and most probably more efficient to store your words in a hash and check for existence of your candidates in the hash.

Something like this:

my $word = "of";
my %stopwords = map { $_ => 1 } qw/ a the of /;
if (exists $stopwords{$word}) {
   print "Stopword $word discarded\n";
}
else{
   print "$word is not a stop word\n";
}
[download]

#!/usr/bin/perl
use warnings;
use strict;

my @words = ("of the blue","the blue of","out of blue");
my @stopwords= ("a","the","of");

foreach my $word (@words)
{
   if (grep{$word =~ /^$_/i or $word =~ /$_$/i}@stopwords)
   {
      print "Stopword $word discarded\n";
   }
   else
   {
      print "$word is not a stop word\n";
   }
}   

__END__
Stopword of the blue discarded
Stopword the blue of discarded
out of blue is not a stop word
[download]

Yet another, and more general, approach:

c:\@Work\Perl\monks>perl -wMstrict -le
"my @stopwords= qw(a the of);
 my ($stopper) =
   map qr{ (?i) $_ }xms,
   join q{ | },
   reverse sort
   map quotemeta,
   @stopwords
   ;
 print $stopper;
 ;;
 my $l_bound = qr{ \A }xms;
 my $r_bound = qr{ \z }xms;
 ;;
 for my $string (
   'of sky blue', 'all blue of', 'out of blue', @ARGV,
   ) {
   printf qq{'$string' };
   if ($string =~ m{ $l_bound $stopper | $stopper $r_bound }xms) {
     print 'has stopper pattern';
     }
   else {
     print 'has no stopper';
     }
   }
"  of  the  a  off  and
(?^msx: (?i) the | of | a )
'of sky blue' has stopper pattern
'all blue of' has stopper pattern
'out of blue' has no stopper
'of' has stopper pattern
'the' has stopper pattern
'a' has stopper pattern
'off' has stopper pattern
'and' has stopper pattern
[download]

Just my two cents here,
for each $word why dont you create a custom regex array instead of just a stopword array? You might like reading this regarding the proper storage of your regexes.
your standard regex could look like something like this:

#!/usr/bin/perl
my $string = $ARGV[0];
if($string =~ m#(\Aof|of\z)#){
    print "matched out at start or end\n";
}
[download]

TIMTOWTDI: with index

#!/usr/bin/env perl 

use strict;
use warnings;
use Test::More tests => 5;

my @yesmatch = ('of', 'of the blue', 'the blue of', 'ending with of');
my @nomatch = ('out of blue');
my @stopwords = qw/a of the/;

for my $phrase (@yesmatch) {
    ok (stopped($phrase, \@stopwords), "$phrase stopped");
}

for my $phrase (@nomatch) {
    ok ((not stopped($phrase, \@stopwords)), "$phrase not stopped");
}

sub stopped {
    my ($phrase, $sw) = @_;
    my $rev;
    for my $word (@$sw) {
        return 1 unless index ($phrase, $word);
        $rev //= reverse $phrase;
        return 1 unless index ($rev, reverse $word);
    }
    return 0;
}
[download]

Note that "the blue of" starts with "the" and so doesn't really test the end-matching so I've added "ending with of" to the test patterns.

This question has been asked and answered here a few times in the past: Super Search it. I especially like bobf's solution using cpan modules.

PS - I do like to see people re-inventing the wheel, because it means they're exercising their technical creativity, and sometimes a novel solution shows up!

Thank you very much for the suggestions, just brilliant!