Here's one example, kind of following along the code layout you already have. In the 'E' case, we simply attempt a regex substitution (s//;), and for the 'Z' entries, we check if we have a match first, capture the match into two parts ($1, $2), and if there is a match, we do the substitution:

while (<>) {
    chomp;    

    # EN.NNNNN 
    # no need for if(), we're not using the capture number vars

    s/E\d\.\d{5}//;
  
    # ZNN.NNN 
    # need if, or it'll warn on no match

    if (/G1 Z\d{1,2}\.\d{3}/){
        s/(G1 Z)(\d{1,2}\.\d{3})/$1-$2/;
    }           
    print "$_\n";
}
[download]

# need if, or it'll warn on no match

No need: no substitution is done, no capture variables are referenced, if no replacement match exists:

c:\@Work\Perl\monks>perl -wMstrict -le
"for my $s ('G1 Z0.050 F7800.000',  'G10 ; retract',) {
   printf qq{'$s' -> };
   local $_ = $s;
   s/(G1 Z)(\d{1,2}\.\d{3})/$1-$2/;
   print qq{'$_'};
   }
"
'G1 Z0.050 F7800.000' -> 'G1 Z-0.050 F7800.000'
'G10 ; retract' -> 'G10 ; retract'
[download]

(Although I think I would prefer to use look-arounds as graff did and just stick a - in.)

---

Give a man a fish:  <%-{-{-{-<

Beautiful! Thanks for the quick response. It would have taken me weeks of trial and error to get to this point- but this helps me learn for next time. Much appreciated! Here is the final working code:

#!/usr/bin/perl -i.before_postproc

# Author  : David Sherwood
# Version : 1.0
# Copyright : none.
#
# Postprocessor for Slic3R Gcode for Laser Cutter

use strict;
use warnings;

# read stdin and any/all files passed as parameters one line at a time

while (<>) {
   
    chomp;    

    # EN.NNNNN 
    # no need for if(), we're not using the capture number vars

    s/E\d\.\d{5}//;
  
    # ZNN.NNN 
    # need if, or it'll warn on no match

    if (/G1 Z\d{1,2}\.\d{3}/){
        s/(G1 Z)(\d{1,2}\.\d{3})/$1-$2/;
           
    }           

    if (/G11/) {
        # if we have an un-retraction line, replace it with laser powe
+r on
        print "M400 ; wait for moves to finish\nM104 S100 ; laser on\n
+";
    }
    
    elsif (/G10/) {
        # if we found a retraction line, replace it with laser power o
+ff
        print "M104 S0 ; laser off\n";
    }
    
    elsif (/G92/) {
        # if we found an extruder reset command line, remove it
        print "";
    }
      
    elsif (/M190/) {
        # if we found a heat bed command line, remove it
        print "";
    }    
           
    else {
    print "$_\n" or die $!;
    }
}
[download]

• You have a comment saying "read stdin and any/all files passed as parameters..." Actually, it should say "or" instead of "and" -- the while(<>) reads either from file names given on the command line, or from STDIN, not both.
• If you think you need to do print or die $! at all, you should do it on every print statement. (But you probably don't need to do it at all. When a print to STDOUT fails, you either don't need to be told, or else you'll get other error messages anyway.)
• Doing print "" is a noisy way of doing nothing at all.

All that aside, I think the device you're looking for is the "look-around" assertions in a regex. Here's a slightly modified version of your code (because sometimes I can't help but change things), with the relevant bits added in the final "else" block:

#!/usr/bin/perl 

use strict;
use warnings;

my @G1x_replace = (
    "M104 S0 ; laser off\n",
    "M400 ; wait for moves to finish\nM104 S100 ; laser on\n",
    );

while (<DATA>) {
    if ( /G1([01])/ ) {
        print $G1x_replace[ $1 ];
    }
    elsif ( /G92|M190/ ) {
        next;
    }
    else {
        s/(?<=G1 Z)(?=\d)/-/g;  # look-behind and look-ahead to insert
+ "-"
        s/E[\d.]+ //g;          # no look-around needed, just delete s
+tuff
        print;
    }
}

__DATA__
G92 E0 ; want to remove all G92 lines (works now)
T1
G1 Z0.050 F7800.000
G10 ; retract
G92 E0
G1 Z0.150 F7800.000
G1 X14.725 Y-8.975 F7800.000
G1 Z0.050 F7800.000
G11 ; unretract
G92 E0
G1 X14.725 Y8.975 E0.01465 F120.000 
G10 ; retract
G92 E0
G1 Z0.150 F7800.000
G1 X-9.585 Y-0.615 F7800.000
G1 Z0.050 F7800.000
G11 ; unretract
G92 E0
[download]

Perl is such a powerful language there are many ways to skin a cat. I use a blunt knife, most of you use a scalpel. :-) I am reading all responses and will learn from them all. Thanks gurus!

#!usr/bin/perl
use warnings;
use strict;
$|=1; #turn off stdout buffering, easier to debug warnings...

my %dispatch = (G92  => sub{return},
                G10  => sub{print "M104 S0 ; laser off\n";},
                G11  => sub{print "M400 ; wait for moves to finish\n";
                            print "M104 S100 ; laser on\n";},
                M190 => sub{return},
                G1   => \&G1,
                );

while (my $line = <DATA>)
{
  chomp $line;
  my ($op,$rest) = split ' ',$line,2;
  $rest //= '';  #define $rest as null string if undefined
  
  if (exists $dispatch{$op})
  {
      $dispatch{$op}->($rest);
  }
  else
  {
      print "$line\n";
  }
}

sub G1
{
   my $rest = shift;
   $rest =~ s/Z/Z-/;
   $rest =~ s/E[\d.]+//;
   print "G1 $rest\n";   
}

=prints:
T1
G1 Z-0.050 F7800.000
M104 S0 ; laser off
G1 Z-0.150 F7800.000
G1 X14.725 Y-8.975 F7800.000
G1 Z-0.050 F7800.000
M400 ; wait for moves to finish
M104 S100 ; laser on
G1 X14.725 Y8.975  F120.000 
M104 S0 ; laser off
G1 Z-0.150 F7800.000
G1 X-9.585 Y-0.615 F7800.000
G1 Z-0.050 F7800.000
M400 ; wait for moves to finish
M104 S100 ; laser on
=cut



__DATA__
G92 E0 ; want to remove all G92 lines (works now)
T1
G1 Z0.050 F7800.000
G10 ; retract
G92 E0
G1 Z0.150 F7800.000
G1 X14.725 Y-8.975 F7800.000
G1 Z0.050 F7800.000
G11 ; unretract
G92 E0
G1 X14.725 Y8.975 E0.01465 F120.000 
G10 ; retract
G92 E0
G1 Z0.150 F7800.000
G1 X-9.585 Y-0.615 F7800.000
G1 Z0.050 F7800.000
G11 ; unretract
G92 E0
[download]