in reply to Re^2: convert columns into matrix and get population count?
in thread convert columns into matrix and get population count?

Hello fasoli,

Yes, it’s easy to tweak the code to generate the desired output format:

#! perl
use strict;
use warnings;
use constant SORT_BY_X => 1;

my (%data, %y_values);

while (<DATA>)
{
    my ($x, $y) = split;
    $x = sprintf "%.2f", $x;
    $y = sprintf "%.2f", $y;
    push @{ $data{$x} }, $y;
    ++$y_values{$y};
}

my @x = sort { $a <=> $b } keys %data;
my @y = sort { $a <=> $b } keys %y_values;

print "--------------\n";
print "  X     Y    Z\n";
print "--------------\n";

if (SORT_BY_X)
{
    for my $x (@x)
    {
        tally($x, $_) for @y;
    }
}
else    # sort by y
{
    for my $y (@y)
    {
        tally($_, $y) for @x;
    }
}

print "--------------\n";

sub tally
{
    my ($x, $y) = @_;
    my  $count  = 0;

    for (@{ $data{$x} })
    {
        ++$count if $_ == $y;
    }

    printf "%5.2f %5.2f %2d\n", $x, $y, $count;
}

__DATA__
 0.1234567890  1.2345678901
52.2456789012 17.2345678901
 0.1234567890  1.2345678901
22.3456789012  3.4567890123
22.35          1.234

[download]

Output:

14:12 >perl 1635_SoPW.pl
--------------
    X     Y  Z
--------------
 0.12  1.23  2
 0.12  3.46  0
 0.12 17.23  0
22.35  1.23  1
22.35  3.46  1
22.35 17.23  0
52.25  1.23  0
52.25  3.46  0
52.25 17.23  1
--------------

14:12 >perl 1635_SoPW.pl

[download]

(But next time you ask the monks for help like this, please show the code you’ve tried, and explain where and how it failed to do what you expected.)

Hope that helps,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

Replies are listed 'Best First'.
Re^4: convert columns into matrix and get population count?
by fasoli (Beadle) on May 26, 2016 at 14:31 UTC
    I know, I know. Whenever I just post a question like "please help me" I feel really bad but in most cases what I've tried is either scribbles on paper or just me racking my brains about *how* to start or, if I actually write some code, just a bunch of syntax errors. The problem is that it's difficult to start thinking like a programmer when nobody ever taught you or gave you some good resources/exercises. I'm trying to learn on my own but my progress is really slow. I've done a few tutorials, read stuff here and there, bought two good books, wrote 10-15 scripts but I still struggle a LOT with simple stuff like this. And it's because I just can't "picture" the task I'm aiming for in form of code. I think this requires either training (computer science degree etc) or years of practice and I have neither, hopefully after so many months I'll start grasping the whole idea better :/ :(
[reply]

      Hello fasoli,

      Don’t be discouraged! Learning to program is a lot like learning to ride a bike or drive a car — you can go only so far by studying the theory, to really learn you need to practice a lot. And be prepared to make mistakes, and to learn from those mistakes.

      ...in most cases what I've tried is either scribbles on paper or just me racking my brains about *how* to start...

      Try turning the scribbles into pseudocode. That will allow you to develop the needed algorithm without having to worry about issues of syntax. When you write pseudocode, you then take on the role of the computer: beginning with sample input, you implement (on paper) each step in the pseudocode exactly as written, then evaluate the result and, if necessary, adjust the pseudocode accordingly. In this way you design an algorithm which will work; that’s half the battle won.

      ...if I actually write some code, just a bunch of syntax errors.

      The compiler is your friend here: get it to alert you to as many errors as possible as early as possible. Start with:

      use strict;
use warnings;

      [download]

      and welcome each error or warning message as though it were a cash windfall. If you have trouble understanding what the messages are getting at, adding:

      use diagnostics;

      [download]

      will help. But, most importantly: proceed in small, self-contained steps. Make a small, simple addition to your code, then test that it does what you expect it to. Revision control and regression testing will help you here. Then, when you run into a problem you can’t solve, you’ll have something (pseudocode, working Perl code, additional non-working Perl code) to show the monks.

      I think this requires either training (computer science degree etc) or years of practice and I have neither...

      I have an IT degree, but I learned the basics of programming before this, and largely on my own. And I have worked in a startup where almost all of the programmers and managers had degrees — including master’s degrees and doctorates — and the best programmer in the whole company — by a long distance — was entirely self-taught with no formal qualifications. But yes, practice is the key (as in so many other areas of life). ;-)

      One of my lecturers had a picture on her office wall: a cartoon of a bird in the process of swallowing a frog. But the frog has its arms around the bird’s throat, preventing it from swallowing. And the caption reads, “Never give up!”

      Hope that helps,

      Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

[reply]
[d/l]
[select]
      I have a suggestion to add to the precious serie presented by the wise Athanasius; read good perl examples for simple tasks.

      In my empirical learning way, during first years i found Perl Cookbook to be very useful to me. The book it is now aged but many programming patterns are stil valid. Put your copy of ModernPerl book byside of it to get a fresh look available.

      L*

      There are no rules, there are no thumbs..
      Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.
[reply]
[d/l]

In Section Seekers of Perl Wisdom