Hi lakshmikant,

Tip #4 from the Basic debugging checklist: Print your values using Data::Dumper to see what they really contain.

use Data::Dumper;
my @numbers = (15,5,7,3,9,1,20,13,9,8,15,16,2,6,12,90);
my @a = join ("," ,(sort {$a <=> $b} @numbers));
print Dumper(\@a);

__END__

$VAR1 = [ '1,2,3,5,6,7,8,9,9,12,13,15,15,16,20,90' ];
[download]

It looks a little misleading, but the quotes tell you: @a is an array with a single element, a string which contains your numbers joined by commas.

Tip: Don't join your array except for printing, e.g.

my @numbers = (15,5,7,3,9,1,20,13,9,8,15,16,2,6,12,90);
my @a = sort {$a <=> $b} @numbers;
print join(",",@a), "\n";
print $a[-2], "\n";

__END__

1,2,3,5,6,7,8,9,9,12,13,15,15,16,20,90
20
[download]

Also, note that $a[-2] gets the second-to-last element; you can get the last one via $a[-1], or even $a[$#a], since $#a gives you the last index of the array @a. (Update: ww demonstrated it here)

Hope this helps,
-- Hauke D

This is a FAQ: Answer: How do I find the index of the last element in an array? (There are multiple answers here)

This may not be the answer you're seeking: if not, please clarify your question.

Update: And this may clarify the answers (here and above):

#!/usr/bin/perl
use 5.018;
use strict;
use warnings;
# 1164677 

my @numbers = (15,5,7,3,9,1,20,13,9,8,15,16,2,6,12,90);
(my @newstring) = sort {$a <=> $b} @numbers;
for (@newstring) {
     print "$_ ";
}

say "\nNumber of elements: " . @newstring;               # number of e
+lements
my $lastindex = $#newstring;
say "\$lastindex: $lastindex";
say "minus 2: " . $newstring[-2];    # "@a" provokes an "unintended in
+terpolation" warning
say "minus 1: " . $newstring[-1];

=head output

1 2 3 5 6 7 8 9 9 12 13 15 15 16 20 90
Number of elements: 16
$lastindex: 15
minus 2: 20
minus 1: 90

=cut
[download]

Hi ww,

When I run the OP's script with use warnings; added I don't see a warning for printing "@a" but I do get one for print $a[-2] since there is only one element in the OP's array. Here is the warning I get:

Use of uninitialized value in print at C:\usr\pm\sort\1164677.pl line 7.

When you print an array inside of double quotes it adds a space by default between the elements or whatever the output field list separator, "$," '$"', is set to. How do I print an array with commas separating each element?

Update: I forgot to mention also at the line (my @newstring) = sort {$a <=> $b} @numbers; you don't need the parentheses since defining an array is already in array context. These are nitpicky comments since your program works and answered the OPs questions, but it's my 2 cents worth.

Update: Fixed the separator as pointed out by AnomalousMonk

When you [interpolate] an array inside of double quotes it adds ... the output field separator, "$,", ...

Array interpolation adds the list separator  $" between elements. See perlvar.

---

Give a man a fish:  <%-{-{-{-<

Your use of join means that the array @a has only one element which is a big long string. Omit the join and you should get a bit farther.

#!/usr/bin/perl
use strict;
use warnings;

use List::Util qw(max); #CORE nothing to install

# changed the order to make max value
# in the middle of @numbers

my @numbers = (15,5,7,3,90,9,1,20,13,9,8,
    15,16,2,6,12);
    
print "max is =", max(@numbers), "\n";

__END__
max is =90
[download]

#!/usr/bin/perl
use strict;
use warnings;

# changed the order to make max value
# in the middle of @numbers

my @numbers = (15,5,7,3,90,9,1,20,13,9,8,
    15,16,2,6,12);
    
@numbers = sort {$a <=> $b} @numbers;

print "max = $numbers[-1]\n";
print "next to max = $numbers[-2]\n";

__END__
max = 90
next to max = 20
[download]

$ perl -e 'print ((sort {$a <=> $b} 15,5,7,3,9,1,20,13,9,8,15,16,2,90,
+6,12)[-1])'
90
[download]

my @numbers = (15,5,7,3,9,1,20,13,9,8,
    15,16,2,6,12,90);
printf ('The maximum number is %s%s', max(@numbers), "\n");

sub max {
    my $first = shift;
    while ($#_ >= 0) { # until list exhausted
        if ($first >= $_[0]) { # keep throwing away inferiors
            shift;
        }
        else {
            $first = shift; # crown the new king
        }
    }
    return $first; # end of list, inferiors exhausted
}
[download]

Quite. It's even simpler if you know that List::Util has been in core for the last decade and has its own max() function.