cipher has asked for the wisdom of the Perl Monks concerning the following question:

Hi, I am having some issues while creating a multidimensional hash. The issue is with split and not the hash itself. Here is my code 
use strict;
use warnings;
use Data::Dumper; 

my %hash;

while (<DATA>) {
    chomp;
    my ($type, $restofstring) = /^type=(\w+) (.+)$/;
    for $restofstring(split){
    my ($key, $val) = split /=/, $restofstring;
    $hash{$type}{$key} = $val;
    }
}
print Dumper \%hash;

__DATA__
type=first a=1 b=2 c=3
type=second d=4 e=5 f=6
type=third g=7 h=8 i=9

[download]
The output is: 
$VAR1 = {
          'third' => {
                       'h' => '8',
                       'type' => 'third',
                       'i' => '9',
                       'g' => '7'
                     },
          'first' => {
                       'type' => 'first',
                       'c' => '3',
                       'b' => '2',
                       'a' => '1'
                     },
          'second' => {
                        'd' => '4',
                        'e' => '5',
                        'type' => 'second',
                        'f' => '6'
                      }
        };

[download]
I was expecting the output to be like this. 
$VAR1 = {
          'third' => {
                       'h' => '8',
                       'i' => '9',
                       'g' => '7'
                     },
          'first' => {
                       'c' => '3',
                       'b' => '2',
                       'a' => '1'
                     },
          'second' => {
                        'd' => '4',
                        'e' => '5',
                        'f' => '6'
                      }
        };

[download]
when I print $restofstring I only see "a=1 b=2 c=3", etc. I am not sure why $key, $value include the $type variable when I think I am exclusively splitting only on variale $restofstring. What am I doing wrong ?

Replies are listed 'Best First'.
Re: Issues with Split
by afoken (Chancellor) on Jun 14, 2016 at 04:08 UTC 
    my ($type, $restofstring) = /^type=(\w+) (.+)$/;
for $restofstring(split){

    [download]

    You are splitting the entire line read ($_), not what (.+) matched ($restofstring). And you are overwriting $restofstring.

    You need a different loop variable, and you need to pass $restofstring as second argument to split.

    Alexander

    --
    Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)
[reply]
[d/l]
[select]
      Thanks, I am still trying to get this fixed based on your recommendations. I will update this thread once I make any progress.
[reply]
        Here is what afoken was talking about -- instead of this: 
            my ($type, $restofstring) = /^type=(\w+) (.+)$/;
    for $restofstring (split) {
        my ($key, $val) = split /=/, $restofstring;
        $hash{$type}{$key} = $val;
    }

        [download]
        you should do this: 
            my ($type, $restofstring) = /^type=(\w+) (.+)$/;
    for $token ( split ' ', $restofstring ) {
        my ($key, $val) = split /=/, $token;
        $hash{$type}{$key} = $val;
    }

        [download]
[reply]
[d/l]
[select]
Re: Issues with Split
by duyet (Friar) on Jun 14, 2016 at 07:41 UTC
    that would be : 
        for my $pair ( split /\s+/, $restofstring )
    {
        my ($key, $val) = split /=/, $pair;
        $hash{$type}{$key} = $val;
    }

    [download]
[reply]
[d/l]
      Thanks! it works. Appreciate your help.
[reply]
Re: Issues with Split
by johngg (Canon) on Jun 14, 2016 at 09:25 UTC

    Another way would be to pass each line of data into a series of nested maps to split on whitespace then on the equals to produce an anonymous hash (hashref) which is passed to a third map. There the value of the "type" key is preserved, the "type" key/value pair deleteed from the hashref and finally the preserved key, with its value being the hashref, passed into %hash.

    use strict;
use warnings;

use Data::Dumper;

open my $inFH, q{<}, \ <<EOF or die $!;
type=first a=1 b=2 c=3
type=second d=4 e=5 f=6
type=third g=7 h=8 i=9
EOF

my %hash =
   map {
       my $key = $_->{ type };
       delete $_->{ type };
       ( $key => $_ );
       }
   map { { map { split m{=} } split } }
   <$inFH>;

close$inFH or die $!;

print Data::Dumper
   ->new( [ \ %hash ], [ qw{ *hash } ] )
   ->Sortkeys( 1 )
   ->Dumpxs();

    [download]

    The output.

    %hash = (
          'first' => {
                       'a' => '1',
                       'b' => '2',
                       'c' => '3'
                     },
          'second' => {
                        'd' => '4',
                        'e' => '5',
                        'f' => '6'
                      },
          'third' => {
                       'g' => '7',
                       'h' => '8',
                       'i' => '9'
                     }
        );

    [download]

    I hope this is helpful.

    Update: Revised wording, s/a series of/nested/.

    Cheers,

    JohnGG

[reply]
[d/l]
[select]
      Thanks JohnGG, I am not that familiar with map but I really appreciate your response and help. This community rocks!
[reply]

Back to Seekers of Perl Wisdom