perl -p0e 's/\n^$|^dn:.*\n//mg; s/cn: //g; s/\norclnetdescstring: /=/g
+'
[download]

Main problems:

   Newline removed
   after, not before
        |      |
        |      |
        v      v
's/\n^$|\n^dn:*$//mg','s/cn: //g','s/\norclnetdescstring: /=/g'
's/\n^$|^dn:.*\n//mg; s/cn: //g; s/\norclnetdescstring: /=/g
            ^        ^
            |        |
           Missing   |
           dot      Optional: no need to switch between Perl and shell
+,
                    using semicolons instead of commas.
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

Thank you, this not only does what I need but also helps me understand syntax better. Just one more question, if you don't mind. I understand why newline should be at the end of the dn: line now (e.g. first line) but why empty line also can't be like that?

It can, i.e. you can start the regex with s/^\n| , but it doesn't change the output. Moving the newline to the end for the dn: line was essential to make it work for the first record.

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

Hi RenMcCourtey,

While what you want to do could be done with a oneliner*, as the code gets more complex it's certainly advisable to use the proper tools for the job.

Apparently ldapsearch outputs in LDIF format, which can be read by, for example, Net::LDAP::LDIF. Here's a quick example I whipped up using the documentation, its output looks like what you want:

use Net::LDAP::LDIF;
my $ldif = Net::LDAP::LDIF->new('nejms.txt', 'r', onerror=>'die');
while (!$ldif->eof) {
    my $entry = $ldif->read_entry;
    print $entry->get_value('cn'), "=",
        $entry->get_value('orclnetdescstring'), "\n";
}
$ldif->done;
[download]

If it's an option for you, you could maybe use Net::LDAP for all your work. (Disclaimer: I don't have experience with the module. It does have a long release history and good reviews, though.)

* I'd strongly recommend the above instead, this is just an example of one way to do it:

$ perl -ne 'next if /^dn:|^\s*$/; s/^cn:\s*(.+)\n/$1/;
  s/^orclnetdescstring:\s*/=/; print' nejms.txt
common_name1=complex_address_line1
common_name2=complex_address_line2
common_name3=complex_address_line3
[download]

Hope this helps,
-- Hauke D

Thanks a lot for both examples. This is actually what I had on mind in a broader sense, like, if I don't scratch my left ear with my right hand, so to speak. Clearly I did.:-) I'll dig deeper into links you posted now.

G'day RenMcCourtey,

As a more general solution to those already provided, when confronted with blocks of data that are to be processed as a single unit, read each block as a single record by localising $/, the input record separator. (See "perlsub: Temporary Values via local()" and "perlvar: Variables related to filehandles".)

Here's how you might do this with your posted data and requested output format:

#!/usr/bin/env perl -l

use strict;
use warnings;

{
    local $/ = "\ndn: ";

    while (<DATA>) {
        /
            ^ cn: \s+ (.*?) $
            .*?
            ^ orclnetdescstring: \s+ (.*?) $
        /msx;
        print join '=', $1, $2;
    }
}

__DATA__
dn: distinguished_name1
cn: common_name1
orclnetdescstring: complex_address_line1

dn: distinguished_name2
cn: common_name2
orclnetdescstring: complex_address_line2

dn: distinguished_name3
cn: common_name3
orclnetdescstring: complex_address_line3
[download]

Output:

common_name1=complex_address_line1
common_name2=complex_address_line2
common_name3=complex_address_line3
[download]