This does what you asked for in the first screenful of your post. I wrote and tested it before noticing there was a lot more to the post, so here it is, maybe it is useful to you:

#! perl -sw
use strict;

my %fhs;

while( <DATA> ) {
    my @bits = split;
    my $abs = abs( $bits[ 3 ] );
    open $fhs{ $abs }, '>', 'output_' . $abs or die $! unless exists $
+fhs{ $abs };
    print { $fhs{ $abs } } $_;
}

__DATA__
-59.077    89.301   115.664       7
-61.251    77.435   117.760      -6
-60.950    71.712   116.061      -7
-56.247    83.685   114.576       1
-59.263    76.107   112.555      -2
-59.895    65.296   111.185       3
-60.141    63.694   111.257      -3
-61.667    63.707   116.937       2
-58.722    60.429   111.307      -1
-57.511    42.922   112.108       6
[download]

Produces:

C:\test>type output_*

output_1


-56.247    83.685   114.576       1
-58.722    60.429   111.307      -1

output_2


-59.263    76.107   112.555      -2
-61.667    63.707   116.937       2

output_3


-59.895    65.296   111.185       3
-60.141    63.694   111.257      -3

output_6


-61.251    77.435   117.760      -6
-57.511    42.922   112.108       6

output_7


-59.077    89.301   115.664       7
-60.950    71.712   116.061      -7
[download]

Hi, thanks for your time. I know, it was a really long post :( I was just testing your answer, it does indeed do part of what I want. My problem is that it's a bit too smart for my perl knowledge :P As you can see I tried to approach it in a very lengthy way because I could understand it better. I'll try to understand exactly what's happening in the code you posted, it is indeed very useful.

Can I ask one more favour? Could you please maybe explain, when/if you find some time to read the rest of my post, what I'm doing wrong with populating the array? I've been googling for hours and don't seem to be able to get it. All I'm trying to write is that all the $match variables are meant to belong in the @match array, or does that make no sense? In my mind, I'm trying to find a way to print $match and have all the values from -10 to 10 printed. Does that sound correct or am I completely off?

Update: Ok this is what I did and it's working! :) I modified my code from my original post (code attempt #2) by adding and editing your contribution. I believe it works correctly for my purpose, I'm now confirming that my output files are correct.

#!/usr/bin/perl
use warnings;
use strict;

my %fhs;

my $molecule = "1kc4";

open my $FILE, '<', 'input_file' or die $!;
while (<$FILE>) {

  chomp;
  my @columns = unpack('a8 a8 a8 a6');
  #print join(" ",map {$_} @columns), "\n";
  #print "@columns[3] \n";
    
  foreach (@columns[$#columns]) {
 
    my $abs = abs( $columns[ $#columns ] );

    open $fhs{ $abs }, '>', "${molecule}_cluster_" . $abs or die $! un
+less exists $fhs{ $abs };
    my $file = $fhs{ $abs };
         
      my $ID = $_;
      my $IDform = sprintf ("%4s", $ID);
     
      my $currentline = $.;
      my $currentlineform = sprintf ("%7s", $currentline);##

      my @selection = (@columns[0..$#columns-1]);
      my $layout = "%10s"x(@selection) . "\n";

      printf $file $IDform . $currentlineform . $layout, @selection;
  }
}
[download]

The output filenames are correct and one of them looks like this:

    8    109   -42.129   -57.475    94.651
    8    110   -45.520   -62.056    90.318
    8    111   -49.196   -63.045    92.577
    8    112   -46.086   -71.753    88.267
   -8    113   -48.146   -76.799    77.638
    8    114   -41.865   -62.567    86.437
[download]

It would be great if you could take a look and let me know if you see something erroneous in my code. Thank you again for your time :)

Are you not getting loads of warnings when you run your code?

For example: Scalar value @columns[$#columns] better written as $columns[$#columns] at ...

---

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority". I knew I was on the right track :)

In the absence of evidence, opinion is indistinguishable from prejudice.

#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;

my %hash;

# make a hash of array based upon last column

while (my $line = <DATA>)
{
   my @tokens = split ' ', $line;
   my $abs_lastcol = abs $tokens[-1];
   my $newline = "$tokens[-1]  $. $tokens[0]  $tokens[1]  $tokens[2]";
   push @{$hash{$abs_lastcol}}, $newline;
}

foreach my $file (sort keys %hash)
{
    print "generate file: $file...\n";
    print "$_\n" for @{$hash{$file}};
}
=prints
generate file: 1...
1  4 -56.247  83.685  114.576
-1  9 -58.722  60.429  111.307
generate file: 2...
-2  5 -59.263  76.107  112.555
2  8 -61.667  63.707  116.937
generate file: 3...
3  6 -59.895  65.296  111.185
-3  7 -60.141  63.694  111.257
generate file: 6...
-6  2 -61.251  77.435  117.760
6  10 -57.511  42.922  112.108
generate file: 7...
7  1 -59.077  89.301  115.664
-7  3 -60.950  71.712  116.061
=cut



__DATA__
-59.077    89.301   115.664       7
-61.251    77.435   117.760      -6
-60.950    71.712   116.061      -7
-56.247    83.685   114.576       1
-59.263    76.107   112.555      -2
-59.895    65.296   111.185       3
-60.141    63.694   111.257      -3
-61.667    63.707   116.937       2
-58.722    60.429   111.307      -1 
-57.511    42.922   112.108       6
[download]

You would need to modify this for the formatting you want (I split your data on whitespace, manipulate it, and then join it again with simple tabs in between), but I believe the following code is one way to do what you are asking.

#!/usr/bin/perl
use warnings;
use strict;

open(my $FILE, '<', 'input_file.txt') or die $!;

my %output_files;
my $line_number = 1;
while (<$FILE>)
{
    chomp;
    my @columns = split;
    my $value = abs($columns[$#columns]);
    
    if(!exists $output_files{$value})
    {
        open($output_files{$value}, '>', "test-out-$value.txt") or die
+ $!;
    }
    my $fh = $output_files{$value};
    
    splice @columns, 0, 0, $columns[$#columns], $line_number;
    pop @columns;
    my $output_line = join "\t", @columns;
    print $fh "$output_line\n";
    
    $line_number++;
}
[download]

EDIT: Didn't notice you moved the last column to be the first column right away, updated code for that.

Just write straight to the files:

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1167222

use strict;
use warnings;

my %files;

while(<DATA>)
  {
  /(.*\S)\s+(\S+)/ or next;
  $files{abs $2} or open $files{abs $2}, '>', "output_@{[abs $2]}.txt"
+ or die;
  printf {$files{abs $2}} "%3d  %3d  %s\n", $2, $., $1;
  }
close $_ for values %files;

system 'more output_*.txt | cat';  # for debugging

__DATA__
-59.077    89.301   115.664       7
-61.251    77.435   117.760      -6
-60.950    71.712   116.061      -7
-56.247    83.685   114.576       1
-59.263    76.107   112.555      -2
-59.895    65.296   111.185       3
-60.141    63.694   111.257      -3
-61.667    63.707   116.937       2
-58.722    60.429   111.307      -1
-57.511    42.922   112.108       6
[download]