You haven't shown any of your preexisting code, so I'll just assume that the whole document is in a single scalar already. Then you can simply a regular expression:

my $string = <<STATEMENT;
Wal-mart talks about its Significant Accounting Policies in its 10k.

Significant Accounting Policies are important for a firm.

Here is a list of the Significant Accounting Policies </b>

1)Lifo

2)Depreciation

3)Expenses
STATEMENT
if( $string =~ m/(.*)Significant\s+Accounting\s+Policies\b(.*)$/m ) {
    print "Found stuff: $2\n";
} else {
    print "Match failed\n";
};
[download]

This relies on the first .* group being greedy and gobbling up as much as possible from the string, thus leaving only the last Significant Accounting Policies instance for the match.

Basically Corion's approach, but uses the  \K operator available from Perl version 5.10 on:

c:\@Work\Perl\monks>perl -wMstrict -le
"use 5.010;
 ;;
 my $str = qq{Wal-mart talks about its Significant Accounting Policies
+ in its 10k. \n}
         . qq{Significant Accounting Policies are important for a firm
+. \n}
         . qq{Here is a list of the Significant Accounting Policies \n
+}
         . qq{1)Lifo \n}
         . qq{2)Depreciation \n}
         . qq{3)Expenses \n}
         ;
 print qq{<<$str>> \n};
 ;;
 my $sap = qr{ Significant \s+ Accounting \s+ Policies }xms;
 ;;
 my ($end_sap) = $str =~ m{ .* $sap \K .* }xmsg;
 print qq{<<$end_sap>> \n};
"
<<Wal-mart talks about its Significant Accounting Policies in its 10k.
Significant Accounting Policies are important for a firm.
Here is a list of the Significant Accounting Policies
1)Lifo
2)Depreciation
3)Expenses
>>

<<
1)Lifo
2)Depreciation
3)Expenses
>>
[download]

Update: On second thought, I think I would write the statement
    my ($end_sap) = $str =~ m{ .* $sap \K .* }xmsg;
as something like
    my $sap_at_end = my ($end_sap) = $str =~ m{ .* $sap \K .* }xmsg;
so that the success of the match will be separately captured. This allows a

    if ($sap_at_end) {
        do_something_with($end_sap);
        }
    else {
        ...    
        }
[download]

Haven't you posted a very similar request to this previously?

Are you able to use those answers previously given to formulate an attempt at what you are trying to accomplish?

I agree the requests are similar. I was just wondering if there is a function that takes the last instance of a string that is repeated multiple times. In the last example the words "statement of accounting policies" was only written once. In no way was I trying to waste anyone's time or get people to write code for me. Thank you for your time!

No worries, it looks like hippo gave you such a function with rindex.

I love it when things get difficult; after all, difficult pays the mortgage. - Dr. Keith Whites
I hate it when things get difficult, so I'll just sell my house and rent cheap instead. - perldigious

What have you tried? What docs have you read?

We're here to help you learn; NOT to write your code.

In the interest of learning, however, see the Tutorials re regular expressions.

Alternately (and a very bad plan, usually), capture all the desired phrases to the end of the file (into an array) and then select the last element of the array. (But, again, you'll need to study regexen.).

Thanks for the reply, I understand where you're coming from. I'm not looking for anyone to write my own code, I'm just wondering if there is a way to match on the last instance of a string.

rindex

use strict;
use warnings;

my $trig = 'Significant Accounting Policies';
my $res;

while (<DATA>){
    if ($_ =~/$trig/i){
      $res = $_;
      next;
    }
    $res.=$_ if $res;
}
print $res;

__DATA__
Wal-mart talks about its Significant Accounting Policies in its 10k.

Significant Accounting Policies are important for a firm.

Here is a list of the Significant Accounting Policies

1)Lifo

2)Depreciation

3)Expenses
[download]

Or a similar approach but using a pointer:

my $trig = 'Significant Accounting Policies';
my @res;
my $pointer;
while (<DATA>){
     $res[$.-1] = $_; # or just: push @res,$_;
     $pointer = $.-1 if /$trig/i;

}
print @res[ $pointer .. $#res ];
[download]

HtH
L*

#!/usr/bin/perl
use warnings;
use strict;

open my $FH, '<', shift or die $!;

my $pos;
while (<$FH>) {
    $pos = tell $FH if -1 != index $_, 'Significant Accounting Policie
+s';
}

if (defined $pos) {
    seek $FH, $pos, 0;
    print while <$FH>;
}
[download]

Update: simplified, as you don't want to print the line containing the string.

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]