Under use warnings; it gives a

Odd number of elements in hash assignment at  ...
[download]

warning so define $SIG{ __WARN__ } to take some action.

Update: Here's a code example.

use strict;
use warnings;

$SIG{ __WARN__ } = sub { die q{Got a warning} };
my %hash = (
            'accents' => 'utf-8',
            'accounting' => 'money',
            'bank' => 'money'.
            'ing' => 'money',
            'perls' => 'perl',
        );
[download]

Update 2: Further updated code as per Camel Book, 4th edn. pp 1041 so as to get the actual warning message

use strict;
use Carp qw{ carp croak confess cluck };
use warnings;

$SIG{ __WARN__ } = sub { confess q{Got a warning: @_} };
my %hash = (
            'accents' => 'utf-8',
            'accounting' => 'money',
            'bank' => 'money'.
            'ing' => 'money',
            'perls' => 'perl',
        );
[download]

Output

Got a warning: @_ at xxxzzz line 5.
        main::__ANON__('Odd number of elements in hash assignment at x
+xxzzz line 6.\x{a}') called at xxxzzz line 6
[download]

Update 3: The sub { confess q{Got a warning: @_} }; should of course have been sub { confess qq{Got a warning: @_} }; so that the @_ interpolates. The output then becomes

Got a warning: Odd number of elements in hash assignment at xxxzzz lin
+e 6.
 at xxxzzz line 5.
        main::__ANON__('Odd number of elements in hash assignment at x
+xxzzz line 6.\x{a}') called at xxxzzz line 6
[download]

Thus the perils of rushing to post before dashing out for an appointment :-/

My thanks to all those who suggested

use warnings;
[download]

and special thanks for the extra

use warnings;
$SIG{ __WARN__ } = sub { confess q{Got a warning: @_} };
[download]

Of course, if you make the same stupid mistake twice (or any even number of times) in the same hash initialization, warnings won't help you:

c:\@Work\Perl>perl -MData::Dump -le
"use warnings;
 use strict;
 ;;
 my %hash = (
   'accents' => 'utf-8',
   'accounting' => 'money',
   'bank' => 'money'.
   'ing' => 'money',
   'foo' => 'bar'.
   'perls' => 'perl',
   );
 dd \%hash;
"
{
  accents    => "utf-8",
  accounting => "money",
  bank       => "moneying",
  barperls   => "perl",
  money      => "foo",
}
[download]

c:\@Work\Perl>perl -MData::Dump -le
"use warnings;
 use strict;
 ;;
 my %hash = qw(
   accents utf-8
   accounting money
   bank money
   ing money
   foo 1
   perls perl
   );
 dd \%hash;
"
{
  accents => "utf-8",
  accounting => "money",
  bank => "money",
  foo => 1,
  ing => "money",
  perls => "perl",
}
[download]

BTW: In case you should feel that my characterization of this mistake as "stupid" is a bit harsh, don't worry: I'm a member of the "Been There, Done That, Got The Scars To Prove It" club too.

But additionally using perltidy would have given you a visual hint, and this also in the even case.

use warnings;

my %hash = (
    'accents'    => 'utf-8',
    'accounting' => 'money',
    'bank'       => 'money' . 'ing' => 'money',
    'perls'      => 'perl'
);
[download]

With use warnings (or -w) you would have gotten: Odd number of elements in hash assignment at ...

... I expected omitting the redundant quotes to produce "bareword" errors under strict

use strict;
use warnings;
use Data::Dump qw/pp dd/;



my %hash =  (
             accents    => 'utf-8',
             accounting => 'money',
             bank       => 'money'.
             bank2      => 'money'.
             bank3      => 'money',
             perls      => 'perl'
            );


dd \%hash;
[download]

but funnily the auto-quoting effect of the fat comma => has higher precedence than the concat operator. (?)

{
  accents => "utf-8",
  accounting => "money",
  bank => "moneybank2",
  moneybank3 => "money",
  perls => "perl",
}
[download]

... I expected omitting the redundant quotes to produce "bareword" errors under strict ... but funnily the auto-quoting effect of the fat comma => has higher precedence than the concat operator. (?)

Um ... operator effect precedence? As different from operator precedence? I don't like that phrasing :D

http://perldoc.perl.org/perlop.html#Comma-Operator says

The special quoting behavior ignores precedence, and hence may apply to part of the left operand:

 print time.shift => "bbb";
[download]

That example prints something like "1314363215shiftbbb" , because the => implicitly quotes the shift immediately on its left, ignoring the fact that time.shift is the entire left operand.

At least this phrasing doesn't bring up precedence, but still seems forced

First part is much better

The => operator (sometimes pronounced "fat comma") is a synonym for the comma except thatit causes a word on its left to be interpreted as a string if it begins with a letter or underscore and is composed only of letters, digits and underscores.

shift is the word on the left, thats the rule, no matter the "entire left operand" , big fat comma quotes the word on the left, the end :)

Well, documented or not that's a good candidate for an extra warning.

Cheers Rolf
_{(addicted to the Perl Programming Language and ☆☆☆☆ :)
Je suis Charlie!}