What your code is doing now is opening the other perl file and giving you a file handle, $fh, to do something with the contents of the file, such as read it. I think what you want to do is not read the file, but execute the file. To do that, you need to execute the file, either through a system call or a backtick call, i.e.

system( 'perl C:/User/MyUser/Desktop/CRA.pl' );

or

`perl C:/User/MyUser/Desktop/CRA.pl`;
[download]

This will run the other perl file in another process.

G'day TheNewGuyShubh,

Welcome to the Monastery.

"I am trying to open ... another Tk perl Gui window ... in my current perl tk Window."

Below, I've referred to the current window as the master and the window (opened in the master) as the slave.

This operation is called embedding. You create the master with either a Tk::Frame, a Tk::Toplevel or a Tk::MainWindow, which has its '-container' option set to a TRUE value. This container widget is where the slave will be embedded: you'll need its ID ($container->id) which is explained in Tk::Widget. You create the slave with a Tk::MainWindow which has its '-use' option set to the container ID.

Important: All of the code below is intended to demonstrate a technique only! It is very much bare-bones code. To make it production-ready, you'll need to add validation, error-checking and so on.

First, let's look at an example slave (pm_1171590_tk_embed_slave.pl). Note that this can be run both as a stand-alone and an embedded application.

#!/usr/bin/env perl

use strict;
use warnings;

use Tk;

my $mw = MainWindow::->new(-use => $ARGV[0] || '');

$mw->Label(-text => 'Slave')->pack;

MainLoop;
[download]

Running this as stand-alone without arguments produces a GUI like this:

+-------+
| Slave |
+-------+
[download]

Attempting to run stand-alone with arguments, generates an error like this:

7fcb5c12a4a0 is not a hash at /.../Tk/MainWindow.pm line 53.
Abort trap: 6
[download]

Now let's look at an example master (pm_1171590_tk_embed_master.pl) that may (or may not) have a specified slave.

#!/usr/bin/env perl

use strict;
use warnings;
use autodie qw{:all};

use Tk;

my $mw = MainWindow::->new();

$mw->Label(-text => 'Embedded slave:')->pack;

if (length $ARGV[0]) {
    my $slave_frame = $mw->Frame(-container => 1)->pack;
    my $container_id = $slave_frame->id;
    open my $pipe, '-|', "$ARGV[0] $container_id";
    MainLoop;
    close $pipe;
}
else {
    my $slave_frame = $mw->Frame()->pack;
    $slave_frame->Label(-text => 'No slave supplied!')->pack;
    MainLoop;
}
[download]

Running without a specified slave.

$ pm_1171590_tk_embed_master.pl
[download]

produces a GUI which looks like

+--------------------+
|  Embedded slave:   |
| No slave supplied! |
+--------------------+
[download]

Running with a specified slave.

$ pm_1171590_tk_embed_master.pl pm_1171590_tk_embed_slave.pl
[download]

produces a GUI which looks like

+-----------------+
| Embedded slave: |
|     Slave       |
+-----------------+
[download]

See also: autodie and open.

I am trying to opening another perl file(I mean run the perl script file which is another Tk perl Gui window) in my current perl tk Window.

:) You should stop trying that and start creating modules