Hello Ganesh Bharadwaj1,

If your input lines are always paired, then Marshall’s approach is probably the best. Otherwise, your logic will need to be a bit more complicated. For example:

use strict;
use warnings;

my $previous_line;
my $exclude = 0;

while (my $current_line = <DATA>)
{
    if (defined $previous_line)
    {
        if ($previous_line =~ /cat/ &&
            $current_line  =~ /dog/)
        {
            $exclude = 1;
        }
        else
        {
            emit_line($previous_line) unless $exclude;
            $exclude = 0;
        }
    }

    $previous_line = $current_line;
}

emit_line($previous_line) unless $exclude;

sub emit_line
{
    my ($line) = @_;

    print $line if defined $line;
}

__DATA__
dog
hippopotamus
cat 
dog
dog
cat
goat
[download]

Output:

17:11 >perl 1695_SoPW.pl
dog
hippopotamus
dog
cat
goat

17:11 >
[download]

Hope that helps,

this reproduces your desired printout. You tell me how close this is to what you really want...

update: But if dog is followed by cat, I want to keep both the lines. You desired output shows the reverse, e.g. cat following dog causes the 2 lines to be deleted.

The basic idea below (with variance for other implementation variations). The basic idea is that it is "hard" to "undo a write" (go backwards and say "oh, I didn't mean that). Keep track of stuff until you are sure that you want to keep it, then write it out. Once it is gone, you can forget about it and start thinking about the next pair of things.

I suspect that you will need to generate a better thought out example if this code doesn't do what you want.

#/usr/bin/perl
use strict;
use warnings;

my @lines;

while (my $cur_line = <DATA>)
{
   push @lines, $cur_line;
   next if @lines <2;
   
   print @lines unless ($lines[0] =~ /dog/ and $lines[1] =~ /cat/);
   @lines = ();
}
=prints
dog
dog
cat
goat
=cut

__DATA__
dog
cat
dog
dog
cat
goat
[download]

1. If cat is followed by dog in the preceding (next?) line, I want to delete both lines.
2. But if dog is followed by cat, I want to keep both the lines.
   What the purpose of this extra condition?

1 cat
2 dog
3 cat
[download]

3 cat
[download]

2 dog
3 cat
[download]

1 cat
2 dog
3 cat
[download]

Please correct the English and elaborate on the examples.

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1171814

use strict;
use warnings;

$_ = join '', <DATA>;

s/^.*cat.*\n.*dog.*\n//gm;

print;

__DATA__
dog
cat 
dog
dog
cat
goat
[download]