Hi kepler,

Try Regexp::Common:

use warnings;
use strict;

use Regexp::Common qw/delimited/;
while (<DATA>) {
    while (/$RE{delimited}{-delim=>'"'}{-keep}/g) {
        my $str = $3;
        print "<$str>\n";
    }
}

__DATA__
nothing
"hello"
foo "bar" quz
"hello" "world"
foo "bar" quz "baz" blah
""
blah "" blah
nothing
[download]

Outputs:

<hello>
<bar>
<hello>
<world>
<bar>
<baz>
<>
<>
[download]

There's also the core module Text::Balanced, but I don't like its API as much.

Hope this helps,
-- Hauke D

FWIW and just as a matter of interest, the reason your OPed regex
    my @strings = $data =~ /\"[^\"]+\"/g;
was "... extracting almost every line..." may be because it will not handle an empty (i.e., zero-length) string properly: the  [^\"]+ regex sub-expression requires at least one non-double-quote character. If there is any  "" empty string in the text, parsing would get "out of sync" by taking the end quote of the empty quote as the start of the spurious body of a quote.

use warnings;
use strict;

use Data::Dump qw(dd);

my $data = do { local $/; <DATA> };

my @strings = $data =~ /\"[^\"]+\"/g;
dd \@strings;

__DATA__
nothing
"hello"
foo "bar" quz
"hello2" "world"
foo2 "bar2" quz2 "baz" blah
blah2 "" blah3
many
lines
of
unquoted stuff
"example 1 for instance"
[download]

c:\@Work\Perl\monks\kepler>perl extract_double_quote_bodies_2.pl
[
  "\"hello\"",
  "\"bar\"",
  "\"hello2\"",
  "\"world\"",
  "\"bar2\"",
  "\"baz\"",
  "\" blah3\nmany\nlines\nof\nunquoted stuff\n\"",
]
[download]

Update: Also note that  /"[^"]+"/g and  /"[^"]*"/g will not properly handle a double-quoted string containing an escaped double-quote (e.g., "x\"y") and will end up "out of sync" in the same way as  /"[^"]+"/g with an empty string.

I just tweaked your regex a bit and used test data from haukex. I like his regexp-common solution, but for something simple, you are close.

use warnings;
use strict;

my $data = do { local $/; <DATA> };

my @strings = $data =~ /\"([^\"]*)\"/g;
   
print map{"<$_>\n"}@strings;

=Prints
<hello>
<bar>
<hello>
<world>
<bar>
<baz>
<>
<>
<example 1 for instance>

=cut

__DATA__
nothing
"hello"
foo "bar" quz
"hello" "world"
foo "bar" quz "baz" blah
""
blah "" blah
nothing
"example 1 for instance"
[download]

It is also worth pointing out that double quotes are not regular expression meta-characters and do not need to be escaped.

johngg@shiraz:~/perl/Monks > perl -Mstrict -Mwarnings -E '
open my $inFH, q{<}, \ <<EOD or die $!;
nothing
"hello"
foo "bar" quz
"hello2" "world"
foo2 "bar2" quz2 "baz" blah
blah2 "" blah3
many
lines
of
unquoted stuff
"example 1 for instance"
EOD

my $data = do {
   local $/;
   <$inFH>;
   };

close $inFH or die $!;

say qq{-->$1<--} while $data =~ m{"([^"]*)"}g;'
-->hello<--
-->bar<--
-->hello2<--
-->world<--
-->bar2<--
-->baz<--
--><--
-->example 1 for instance<--
johngg@shiraz:~/perl/Monks >
[download]

I hope this is helpful.