#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use XML::DOM;


my $doc = 'XML::DOM::Parser'->new->parsefile(shift);
say $_->getAttribute('id') for grep 3464 eq $_->getAttribute('sigid'),
    $doc->getElementsByTagName('signal');
[download]

If your XML file is really huge, you might need to switch to a pull or SAX parser. I'm not sure whether XML::DOM provides such an interface.

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

As it says, XML::DOM is not a streaming or event parser, it's a document parser. So, it stores the entire XML in memory and works the tree. Not very useful for the task at hand, is it? :-)

Personally, I would use XML::DOM::XPath, locate the element through the appropriate XPath query (//signal[@sigid="3464"]) and then output its value.

Got your point but for some reason have to use XML::DOM only. Can you help me with that ?

Looking at the documentation of XML::DOM, it shows the use of ->getElementsByTagName. The simplest approach would then be something like:

my $signals = $doc->getElementsByTagName('signal');
my @by_id = grep {
                my $sigid= $_->getAttributeNode('sigid');
                if( $sigid ) {
                    $sigid == 3464
                } else {
                    0  # no sigid attribute, no match
                }
            } map { $signals->item($_) } 0..$signals->getLength()-1
[download]

I still recommend using an XPath query.

Personally i think XML::DOM is not going to be the right solution, if your input xml file is very large. My perfered choice for parsing xml is XML::Twig. I am using it to parse very large files, and it is doing it quickly with a low memory usage. The same may apply for other modules, however i am most familiar with XML::Twig.

use strict;
use warnings;
use Data::Dumper;
#use Data::Dumper::Concise; # i prefer Data::Dumper::Concise
use XML::Twig;

# individually process each <signal> element
sub signal_handler {
        my ($data, $twig, $elem) = @_;

        # get the attributes of $elem (<signal>)
        my $atts = $elem->atts();  

        if ($atts->{'sigid'} == 3464) {
                print "Found <signal> with sigid == 3464:\n",$elem->sp
+rint(),"\n";
                print "<PRESS ENTER TO CONTINUE>";<STDIN>;
        }

        # if you want to access the element in a way similar to XML::S
+imple:
        my $xml_simple_style_elem = $elem->simplify();

        # check out the simplified structure:
        print Dumper($xml_simple_style_elem);
        print "<PRESS ENTER TO CONTINUE>";<STDIN>;

        # Example for Data Collection:
        my ($sigid, $id) = @{$atts}{qw/sigid id/};
        if (defined $sigid and defined $id) {
                $data->{sigid_id_count}{$sigid}{$id}++;
        }

        # get all elements below <signal> which are called <foo>
        my @foo_subelements  = $elem->descendants('foo');

        $twig->purge; # explicitly free the memory
};

sub main {
        my $fn = shift @ARGV;
        my %collected_data;

        my $twig = XML::Twig->new(
                twig_roots => {
                        'signal'     =>  sub {signal_handler(\%collect
+ed_data, @_);},
                },
        );
        eval {
                $twig->parsefile($fn);
        };
        if ($@) {
                print STDERR "Failed to parse '$fn' ($@)\n";
        }
        if (%collected_data) {
                print "I collected the following data:\n",Dumper(\%col
+lected_data);
        }
}
main();
[download]

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use XML::LibXML::Reader;

my $file = shift;

my $reader = 'XML::LibXML::Reader'->new(location => $file)
    or die "Cannot read $file.\n";
while ($reader->nextElement('signal')) {
    say $reader->getAttribute('id')
        if '3464' eq $reader->getAttribute('sigid');
}
[download]

Similarly, in XML::XSH2, a wrapper around XML::LibXML :

stream :N :f file.xml select signal[@sigid=3464] { echo @id }
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]