But if you build the hash for this purpose, then, the best is probably to build it the right way from the start:

my %colours = ( 1 => "blue", 2 => "green", ... );
[download]

Yet, if your indices are all small integers, you might as well use an array:

my @colours = qw/ blue green red pink purple /;
[download]

my @colours = qw/ nil blue green red pink purple /;
[download]

Hello bananabread, and welcome to the Monastery!

You need a hash in which the keys are numbers and the values are the corresponding colours. If you already have the hash %colours as shown (and need to keep it for some other reason), you can create a reversed hash easily using Perl’s built-in reverse function. As an illustration:

use strict;
use warnings;
use Data::Dump;

my  %colours = ( blue => "1", green => "2", red => "3", pink => "4", p
+urple => "6" );
my  %reverse_colours = reverse %colours;
dd \%reverse_colours;

printf "The colour corresponding to %d is %s\n", 1, $reverse_colours{1
+};
[download]

Output:

13:32 >perl 1703_SoPW.pl
{ 1 => "blue", 2 => "green", 3 => "red", 4 => "pink", 6 => "purple" }
The colour corresponding to 1 is blue

13:32 >
[download]

See “How do I look up a hash element by value?” in perlfaq4.

Hope that helps,

Others have pointed out that your %colours hash would be much more suitable if it was reversed. However, you can still obtain the colour from the chosen number with the hash as it stands by using keys and grep.

johngg@shiraz:~ > perl -Mstrict -Mwarnings -E '
my %colours    = (
   blue   => q{1},
   green  => q{2},
   red    => q{3},
   pink   => q{4},
   purple => q{5},
   );

my @numbers    = qw{ 1 2 3 4 5 };
my $pick       = $numbers[ int rand @numbers ];
say qq{Number $pick chosen};

my( $colour )  = grep { $colours{ $_ } eq $pick } keys %colours;
say qq{Colour is $colour};'
Number 2 chosen
Colour is green
[download]

Of course, building the hash the right way in the first place is by far the best approach.

And of course, this approach allows a number to represent more than one color, if this is necessary:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $color = 7;
 ;;
 my %colors = qw(blue 1  green 7  red 3  pink 7  purple 6);
 ;;
 my @picked = grep { $colors{$_} eq $color } keys %colors;
 print qq{color(s) picked by $color: @picked};
"
color(s) picked by 7: green pink
[download]

---

Give a man a fish:  <%-{-{-{-<