Hi,

I am a bit confused with multi line matching, how can I get the value of property name "Text" to match since it spans across multiple lines?

Use something like XML::Twig it knows how to do that already :)

#!/usr/bin/perl --
use strict;
use warnings;
use XML::Twig;

my $xml = q{<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<set name="01" id="test" catId="81679" >
   <cdsets>
      <cdset id="cdset" name="CD Compilation">
         <property name="Own"        value=""/>
         <property name="Type"        value="Record"/>
         <property name="Text"        value="Sample text

more sample text
more more same text]."/>
         <property name="Unique"         value="yes"/>
      </cdset>
   </cdsets>
</set>
};


XML::Twig->new(
    twig_roots => {
        'cdset' => sub {
            print $_->path, ' ';
            printf "id(%s)=%s\n", $_->att('id'), $_->att('name');
        },
        'cdset/property' => sub {
            print $_->path, ' ';
            print $_->att('name'), '=', $_->att('value'),"\n";
        },
    },
)->parse( $xml );

__END__
/set/cdset/property Own=
/set/cdset/property Type=Record
/set/cdset/property Text=Sample text  more sample text more more same 
+text].
/set/cdset/property Unique=yes
/set/cdset id(cdset)=CD Compilation
[download]

Thanks!

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use XML::LibXML;

my $dom = 'XML::LibXML'->load_xml(IO => *DATA{IO});
for my $property ($dom->findnodes('/set/cdsets/cdset/property')) {
    say join ' -> ', @$property{qw{ name value }};
}

__DATA__
<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<set name="01" id="test" catId="81679" >
   <cdsets>
      <cdset id="cdset" name="CD Compilation">
         <property name="Own"        value=""/>
         <property name="Type"        value="Record"/>
         <property name="Text"        value="Sample text

more sample text
more more same text]."/>
         <property name="Unique"         value="yes"/>
      </cdset>
   </cdsets>
</set>
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

This

#!/usr/bin/perl
use strict;
use warnings;

my $data = join "", <DATA>;   # slurp DATA-section

while( $data =~ /<property name="(.*?)"\s+value="(.*?)"/gs ) {
  print qq|$1 -> "$2"\n|;
}


__DATA__
<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<set name="01" id="test" catId="81679" >
   <cdsets>
      <cdset id="cdset" name="CD Compilation">
         <property name="Own"        value=""/>
         <property name="Type"        value="Record"/>
         <property name="Text"        value="Sample text

more sample text
more more same text]."/>
         <property name="Unique"         value="yes"/>
      </cdset>
   </cdsets>
</set>
[download]

Own -> ""
Type -> "Record"
Text -> "Sample text

more sample text
more more same text]."
Unique -> "yes"
[download]

G'day yoda54,

"I am a bit confused with multi line matching, how can I get the value of property name "Text" to match since it spans across multiple lines?"

The main problem with your code is that you're not dealing with multilines. You're reading one line at a time from the DATA filehandle. This is determined by the input record separator^[$/] which is set to newline by default: you'd need to change this — I'd recommend localising the change in an anonymous block.

Here's the technique:

#!/usr/bin/env perl

use 5.014;
use strict;
use warnings;

my $re; BEGIN { $re = qr{(?msx: name="([^"]+)" .*? value="([^"]*)" )} 
+}

{
    local $/ = '/>';

    while (<DATA>) {
        next unless /$re/;
        say 'name=[', $1, ']; value=[', $2 =~ y/ \n/ /rs, ']';
    }
}

__DATA__
<property name="Own"        value=""/>
<property name="Type"        value="Record"/>
<property name="Text"        value="Sample text

more sample text
more more same text]."/>
<property name="Unique"         value="yes"/>
[download]

Output:

name=[Own]; value=[]
name=[Type]; value=[Record]
name=[Text]; value=[Sample text more sample text more more same text].
+]
name=[Unique]; value=[yes]
[download]

Thanks!