in reply to Re: First word
in thread First word

Thanks for your quick reply. I modified the script as follows: 

my(@kmers);
for my$x (@AoA){
    for my$y (@$x){
        push @kmers, $y =~ /^(\w+)/; 
        print @kmers."\n";
        }
    }

[download]

but I am getting this output: 1 2 3 4 5 6 7 8 9 10 11 12 ... Is it printing just the scalar value? If so, why is that? I am often having this problem in other situations

Replies are listed 'Best First'.
Re^3: First word
by GotToBTru (Prior) on Oct 21, 2016 at 12:39 UTC

    Try:

    print "@kmers\n";

    But God demonstrates His own love toward us, in that while we were yet sinners, Christ died for us. Romans 5:8 (NASB)
[reply]
[d/l]
Re^3: First word
by hippo (Archbishop) on Oct 21, 2016 at 12:40 UTC

    Since you haven't provided an SSCCE it is rather hard to say with certainty but the suspicion has to be that your @AoA is incorrectly formed and may not even be an AoA at all. Perhaps it is a deeper structure but that's pure speculation since you have not shared it.

    Update: GotToBTru looks to have found the likely reason. I can't imagine why Anonymonk changed that from my example.

[reply]
[d/l]
Re^3: First word
by Marshall (Canon) on Oct 22, 2016 at 00:56 UTC
    GotToBTru is right. I'll tell you why...
    With print @kmers."\n";, the "." (string concatenation) forces @kemers into a scalar context, which is the number of elements in the array. If you use a comma, print @kmers,"\n"; you get the contents of the @kmers array, but without the automatic output space separator. Using, print "@kmers\n"; is probably what you want? See Examples below...

    Of course, you probably want to move the print outside of the loop so that you just get the final result, not the intermediate results for each element? 

    #!/usr/bin/perl
use strict;
use warnings;

my @AoA = (
    ['firstRowCol1 asdf87534', 'firstRowCol2 junk lj6t90'],
    ['secondRowCol1 mnhibvygt7','secondRowCol2 7d7d5434']
);

my(@kmers);
for my $x (@AoA)
{
    for my $y (@$x)
    {
        push @kmers, $y =~ /^(\w+)/; #first word of each element 
        print "@kmers\n";
    }
}

__END__
In the above code,

print @kmers."\n"; #prints...
1
2
3
4

print @kmers,"\n";  #prints...
firstRowCol1
firstRowCol1firstRowCol2
firstRowCol1firstRowCol2secondRowCol1
firstRowCol1firstRowCol2secondRowCol1secondRowCol2

print "@kmers\n";  #prints...
firstRowCol1
firstRowCol1 firstRowCol2
firstRowCol1 firstRowCol2 secondRowCol1
firstRowCol1 firstRowCol2 secondRowCol1 secondRowCol2

    [download]
    Update: I noticed that you were using tab characters in the code. This is not a good idea because a number of problems arise. Not the least of which is that there is no standard definition of "how long a tab should be". In your program editor, set the option "convert tabs to spaces". That way the indentation will look the same to me as it does to you even though I'm using a different editor.

    Another Update: As per the post from Hippo, there are certainly some folks who disagree with my opinion about tabs. I don't want to re-hash this, especially since this point was not a focus of the OP's original question. For those interested, read the thread comments and make up your own mind.

[reply]
[d/l]
[select]
      I noticed that you were using tab characters in the code. This is not a good idea because ...

      For clarity, the use of tabs is a personal decision (or a coding standards one). See Tabs vs Spaces lets give this a go for when this was all hashed out previously, so there's no point in going over it again here. Just note that the above is Marshall's opinion on the matter only.

[reply]

In Section Seekers of Perl Wisdom