Hi

My team is using TinyMCE in a web-application to create templates for HTML emails. (not my idea)

We've been confronted with strange errors where whitespaces occasionally where introduced in the middle of the emails after sending.

This was particularly ugly b/c sometimes HTML tags where broken, like in </sp an>

A closer investigation revealed that by RFC lines in Emails are not allowed to have more than 1000 characters (only fair) and that TinyMCE sometimes tended to glue HTML code into one "physical" line, especially when

• "visual" lines where separated by <br> tags
• or when the text was introduced by cut&paste from other applications.

So I need a pragmatic solution to avoid such "monster" lines after editing an email text.

I came up with the following idea, which should be as safe as possible without starting to parse HTML

1. prepend a \n before every <br> tag
2. if overlong unbroken text-chunks remain, replace the last blank with a \n
3. return an error to the user if the later fails

The idea is to change a minimal amount of HTML code in a transparent way.

(I suppose that <pre> -tags are not used with monster lines and that the inner code of HTML and CSS doesn't distinguish if a whitespace is a blank or a line-break)

That's the code I came up with, comments are welcome! :)

use strict;
use warnings;
use Data::Dump qw/pp dd/;


my $body = <<'__HTML__';

<br /><br/><br><break>
asdfghjk rtz ertzuiop rtzuiopu rtzuiop tzuiopu rtghljh
AaaaaaaaaaaaaaABbbbbbbbbbbbbbbB
__HTML__


#pp $body;

my $err = FC012_shorten_lines_mail_body(\$body);

#pp $body;

print $err,$body;



sub FC012_shorten_lines_mail_body {
   my ($body_ref) = @_;


   my $err = undef;
   # callback with closure for error
   my $replace_last_whitespace = sub {
      my ($chunk) = @_;
      # dd "CHUNK: $chunk";
      my $ok = $chunk =~ s/ ([^\s]*)$/\n$1/;

      unless ($ok) {
         my $snip_length = 4;           #  for testing, should be 40
         my $start_chunk = substr ($chunk,0,$snip_length);
         my $end_chunk   = substr ($chunk,-$snip_length,$snip_length);
         $err .= "Failed to shorten chunk >>$start_chunk...$end_chunk<
+<\n";
      }
      return $chunk;
   };

   # --- prepend all <br>-tags with real linebreak
   $$body_ref =~ s#(<br[ />])#\n$1#g; 

   # --- find all reamining chunks in one line and
   #     replace last whitespace with \n

   my $length = 15;                     # for testing, should be 998

   $$body_ref =~ s/([^\n]{$length})/ $replace_last_whitespace->($1) /g
+e;

   # --- return potential error message
   return $err ;
}
[download]

--->

Failed to shorten chunk >>Aaaa...aaaA<<
Failed to shorten chunk >>Bbbb...bbbb<<


<br />
<br/>
<br><break>
asdfghjk rtz
ertzuiop
rtzuiopu rtzuiop
tzuiopu rtghljh
AaaaaaaaaaaaaaABbbbbbbbbbbbbbbB
[download]