First of all, congratulations for the good sense to use strict and warnings.

Let's walk through your script's run:

1. $test is declared and defined with the string of true.
2. $lib is declared but not defined (meaning, no value is assigned to initialize it. When a variable is not defined, in Perl, loosely speaking, it contains undef.
3. GetOptions is invoked, and detects that the test flag appeared on the command line with a value of "true". The libFile flag was NOT provided on the command line, so no value is assigned to $lib
4. The first conditional detects that $test contains true, so we move into the second conditional.
5. The second conditional attempts to dereference $lib. That is, it attempts to access the array reference contained in $lib. But wait, $lib doesn't contain an array reference. It doesn't contain anything aside from undef.
6. Since Perl cannot dereference an entity that does not contain a reference, it throws an error and exits, unable to comply with the request. It simply will not pull a rabbit out of a hat (particularly when using strict, as you are correctly doing).

Where you may be getting confused is over the concept of Perl's autovivification. This does work:

use strict;
use warnings;

my $foo;
push @$foo, 'bar';
[download]

But this does not work:

use strict;
use warnings;

my $foo;

my @bar = @$foo;
[download]

To answer your question on how to initialize lib :

my $lib =[]; # A reference to an empty array
[download]

Another alternative is to check for $lib to be defined before checking scalar @$lib.

As others have pointed out, your problem is you are asking Perl to dereference a reference to a variable that has not been defined.

This demonstrates one of the benefits of using full deference syntax rather than omitting the optional braces:

%{ $href } # better than %$href
@{ $aref } # better than @$aref
[download]

if ( scalar @{ $lib || [] } ) {
    ...
}
[download]

Including this because I did just get bitten by it recently:
Also, be cautious of using scalar to test whether an array is populated. If you need to know whether there are non-empty values in the array, scalar can trip you up.

$ perl -Mstrict -E 'my $aref = [ "", undef ]; say scalar @{ $aref || [
+] } ? "True" : "False";'
True
[download]

$ perl -Mstrict -E 'my $aref = [ "", undef ]; say scalar ( grep { leng
+th $_ } @{ $aref || [] } ) ? "True" : "False";'
False
[download]

the full syntax allows you to put expressions in the dereference... I did not know that, after too many years of coding Perl to admit. Thanks!