my $re1 = qr{([0-4])};
my $re2 = qr{([5-9])};

my %hash = ("$$re1" => "foo", "$$re2" => "bar");

$_ = "-5-";
for my $re (keys %hash) {
    print "match: ($1) $hash{$re}\n" if /$re/;
}

# outputs:
# match: (5) bar
[download]

Dave.

My problem has come in being able to recognize when I have a regex vs. a regular string in a key. I tried using a "ref $re", looking for a Regexp (no go), and I tried looking for "qr" -- only works if you store qr as a string initially, and try to evaluate it later. That's what I ended up trying to do. Looking for something like "(?" makes me a bit less comfortable than searching for "qr", though -- it looks a bit sloppy for some reason, but maybe I'm just not used it.

I tried using a "ref $re", looking for a Regexp (no go) ...

I'm not sure what this means. Again, my take:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $re_obj = qr{([0-6BS])};
 if (ref $re_obj) {
   print 'A: reference: ', ref $re_obj;
   }
 else {
   print 'A: not a reference';
   }
 ;;
 my $re_str = '' . $re_obj;
 if (ref $re_str) {
   print 'B: reference: ', ref $re_str;
   }
 else {
   print 'B: not a reference';
   }
"
A: reference: Regexp
B: not a reference
[download]

---

Give a man a fish:  <%-{-{-{-<

G'day perl-diddler,

Firstly, I suggest you read "perlop: Regexp Quote-Like Operators". There are certain things about qr that are non-standard and non-intuitive: I suspect you're making understandable, yet incorrect, assumptions.

In the following, I've addressed all (I think) of the points you've raised and hopefully cleared up any misunderstandings.

When used as a string, qr acts like a string:

$ perl -E 'my $re = qr{([0-6BS])}; say $re'
(?^u:([0-6BS]))
[download]

When used as a reference, qr acts like a reference:

$ perl -E 'my $re = qr{([0-6BS])}; say ref($re)'
Regexp
[download]

When used as a hash key, which is a string, qr acts like a string:

$ perl -E 'my $re = qr{([0-6BS])}; my %x = ($re, 1); my @y = keys %x; 
+say $y[0]'
(?^u:([0-6BS]))
[download]

The hash key is just a string, not a reference:

$ perl -E 'my $re = qr{([0-6BS])}; my %x = ($re, 1); my @y = keys %x; 
+say "|", ref($y[0]), "|"'
||
[download]

The next two points directly address the title of your post: "how to use string RE (against $_ and capture)".

You can use qr in a match like '/COMPILED_QR_RE/':

$ perl -E 'my $re = qr{([0-6BS])}; $_ = "B"; /$re/; say $1'
B
[download]

You can use a hash key string in a match like '/STRING_RE/':

$ perl -E 'my $re = qr{([0-6BS])}; my %x = ($re, 1); my @y = keys %x; 
+$_ = "B"; /$y[0]/; say $1'
B
[download]

See also: perlre and ref.

Here's my take:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $re_obj = qr{([0-6BS])};
 my $re_str = '' . $re_obj;
 print $re_str;
 ;;
 if ('ABC' =~ $re_str) {
   print qq{match, \$1 captured '$1'};
   }
 else {
   print 'no match';
   }
"
(?^:([0-6BS]))
match, $1 captured 'B'
[download]

What I meant is how, after "$re_str" has been stringified, would the code know the string is meant to be used as a regexp instead of a direct compare. The keys represent command-line flags or switches after one dash has been removed, but in this case I wanted the key to match several possibilities.

As I noted in the other response, it looks like searching for '(?' at the beginning of the expression is the best way.

... how, after "$re_str" has been stringified, would the code know the string is meant to be used as a regexp instead of a direct compare.

The code "knows" because the string is used by a   =~  m//  s/// (I think that's all of them) matching operator. And what's a "direct compare" anyway?

---

Give a man a fish:  <%-{-{-{-<

... multiple matches in "re_str" being captured ...

c:\@Work\Perl\monks>perl -wMstrict -le
"use Data::Dump qw(pp);
 ;;
 my $re_str1 = '' . qr{ [0-6BS] }xms;
 print 'A: reference: ', ref $re_str1 if ref $re_str1;
 ;;
 my $str = 'ab3c64dSeBf';
 my @captures = $str =~ m{ $re_str1 }xmsg;
 pp @captures;
 ;;
 my $re_str2 = '' . qr{ [a-f] }xms;
 print 'B: reference: ', ref $re_str2 if ref $re_str2;
 ;;
 my ($one, $two, $three) = $str =~ m{ ($re_str1) ($re_str2) ($re_str1)
+ }xms;
 pp $one, $two, $three;
"
(3, 6, 4, "S", "B")

(3, "c", 6)
[download]

As soon as I turn my re_str into a string though I start having problems. eval m{$re_str}

Have you read eval? What string does a m{$re_str} return , are you sure you want to eval that user supplied input?

See (user supplied regex substitution without eval)

In your first code sample, you have:

my $re_str=qr{([0-6BS])};
$_="B";
my $ans;
if (eval m{$re_str})
[download]

Why are you using eval? It should not be needed.

In your second code sample:

my $re_str="qr{([0-6BS])}";
$_="B";
my $ans;
if (eval m{$re_str})
[download]

The m{$re_str} will be interpreted as m/qr{(&#x005b;0-6BS&#x005d;)}/ which is looking to match something that starts with "qr". (And I'm not sure how the "{([0-6BS])}" will get interpreted as. "{" and "}" in a regex are normally used to quantify the number of matches.)

To store a regex as a hash key, you could prefix the regex with a character that won't otherwise appear as the first character of any of your hash keys. So, something like this:

#not tested, YMMV
for $key (keys %options)
{
    if ($key =~ s/^#//)
    {
        if (/$key/)
        {
            print "Match: $1\n";
        }
    }
    else
    }
        if ($_ eq $key)
        {
            print "Equals: $1\n";
        }
    }
}
[download]

... I'm not sure how the "{([0-6BS])}" will get interpreted as. "{" and "}" in a regex are normally used to quantify the number of matches.

Apparently, if the RE compiler can't see anything in the regex that looks like a count or count range, it just gives up on the whole counted quantifier thing and takes the curlies as literal characters.

c:\@Work\Perl>perl -wMstrict -le
"$_ = 'xxqr{S}xx';
 print qq{matched '$&', \$1 is '$1'} if m/qr{([0-6BS])}/;
"
matched 'qr{S}', $1 is 'S'
[download]

(Tested under ActiveState 5.8.9, Strawberry 5.14.4.1.)

To store a regex as a hash key, you could prefix the regex with a character that won't otherwise appear as the first character of any of your has keys.

I still prefer some sort of separate tag to distinguish pattern from exact matching:

c:\@Work\Perl>perl -wMstrict -MData::Dump -le
"my %options = (
   qr{ x (Y) z }xms => { type => 'pattern',  name => 'foo', },
   '(?x) x (Y) z '  => { type => 'pattern',  name => 'fum', },
   'xYzzy'          => { type => 'exact',    name => 'bar', },
   'zzzzz'          => { type => '?????',    name => 'zot', },
   );
 dd \%options;
 ;;
 $_ = 'xYzzy';
 for my $p (sort keys %options) {
   my ($p_type, $p_name) = @{ $options{$p} }{ qw(type name) };
   if ($p_type eq 'pattern') {
     if ($_ =~ $p) { print qq{'$p_name' pattern match of $p, \$1 is '$
+1'}; }
     }
   elsif ($p_type eq 'exact') {
     if ($_ eq $p) { print qq{'$p_name' exact match of '$p'}; }
     }
   else {
     die qq{unknown: $p; type '$p_type'; name '$p_name'};
     }
   }
"
{
  "(?^msx: x (Y) z )" => { name => "foo", type => "pattern" },
  "(?x) x (Y) z " => { name => "fum", type => "pattern" },
  "xYzzy" => { name => "bar", type => "exact" },
  "zzzzz" => { name => "zot", type => "?????" },
}

'foo' pattern match of (?^msx: x (Y) z ), $1 is 'Y'
'fum' pattern match of (?x) x (Y) z , $1 is 'Y'
'bar' exact match of 'xYzzy'
unknown: zzzzz; type '?????'; name 'zot' at -e line 1.
[download]

(Test under same Perl versions as above.)

---

Give a man a fish:  <%-{-{-{-<