jahero has asked for the wisdom of the Perl Monks concerning the following question:

Hello wise monks!

I would like to ask a (probably) newbie question in regards to namespaces and names collisions.

Lets say that I have something like this in my code (shortened, incomplete).

    package Something::BufferedRead;
    use strict;
    use warnings FATAL => 'all';
    use File::Basename;

    our $VERSION                   = 1.00;
    my $BUFFER_SIZE                = 1048576;

    sub new {
        my $class = shift;
        my @data = @_;
        
        my $self = {};
        bless $self, $class;    
        return $self;
        
    }

    sub basename {
        my $self = shift;
        return basename($self->{cfg}->{filename});
    }

[download]

Now this fails to compile since 'basename' collides with name of sub imported from module File::Basename. Obvious solution would be to change name of my sub, for example to 'base_name', however I want to understand what exactly is going on, and how to prevent this from being pain in the future.

Which leads me to the real question.

Thank you for your time!

Replies are listed 'Best First'.
Re: Namespaces & colliding names
by Athanasius (Cardinal) on Nov 08, 2016 at 08:24 UTC

    Hello jahero, and welcome to the Monastery!

    You can control what is imported by specifying imports explicitly as part of the use declaration. For example, if you change your code to:

    use File::Basename ();

    [download]

    then the basename function in File::Basename will not be imported, so defining your own sub basename will not produce a namespace collision. If you then wanted to call the function of that name in File::Basename, you would need to qualify it fully:

    File::Basename::basename(...);

    [download]

    See the documentation for use.

    Hope that helps,

    Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

[reply]
[d/l]
[select]

      Yes, this helps. Thank you for explanation!

[reply]
Re: Namespaces & colliding names
by kcott (Archbishop) on Nov 08, 2016 at 09:26 UTC

    G'day jahero,

    Welcome to the Monastery.

    ++Athanasius showed in his response how to stop all imports with: 

    use File::Basename ();

    [download]

    However, there may be cases where you only want to stop some, but not all, imports. Still using File::Basename as an example, let's say you wanted its dirname() function. You can specify importation of that function like this: 

    use File::Basename qw{dirname};

    [download]

    Module documentation will often identify which functions are exported by default and which are optionally exported; however, presence of this information is by no means guaranteed. You can check for yourself by looking at the source code: @EXPORT lists the default exports and @EXPORT_OK lists the optional ones. For example, the File::Basename source code shows four default exports: 

    @EXPORT = qw(fileparse fileparse_set_fstype basename dirname);

    [download]

    See Exporter for a lot more information on this including advanced features. For instance, to exclude basename() only, you could write: 

    use File::Basename qw{!basename};

    [download]

    — Ken

[reply]
[d/l]
[select]
      Thank you, I was not aware that one can also exclude certain parts of the module from import.
[reply]
Re: Namespaces & colliding names
by shawnhcorey (Friar) on Nov 08, 2016 at 14:18 UTC

    You could also rename File::Basename::basename

    use File::Basename ();
local *file_basename = \&File::Basename::basename;

say file_basename( $0 );

    [download]
[reply]
[d/l]
[select]
      This leads me to understanding another concept I had trouble understanding - typeglobs. Thanks for that.
[reply]

Back to Seekers of Perl Wisdom