in reply to Re^2: Perl Tk label references
in thread Perl Tk label references

I was able to fix one problem. the Label reference syntax was wrong. The correct way was \$$ref_hash{'VM-1'}. But the clear of the hash when I click on the "clear" button still does not update my Label?? 

use Tk;
require Tk::Entry;
require Tk::Button;

my $mw = MainWindow->new();

my %work = (
    "VM-1" => "da923",
    "VM-2" => "dz427");

main_display(\%work);

MainLoop;

# -----------------------------------------------------
sub main_display {
    my $ref_hash = shift(@_);

    my $lab1 = $mw->Label(-textvariable => \$$ref_hash{'VM-1'},
                                            -relief => 'sunken',
                                            -width => 10,
                                            )->pack();
    my $lab2 = $mw->Label(-textvariable => \$$ref_hash{'VM-2'},
                                            -relief => 'sunken',
                                            -width => 10,
                                                )->pack();
    my $but = $mw->Button(-text=>'clear', -command=> [sub{
                                          %{$ref_hash} = ();
                                          $mw -> update;
                                           }] )->pack();

}

[download]

Replies are listed 'Best First'.
Re^4: Perl Tk label references
by pryrt (Abbot) on Nov 10, 2016 at 22:17 UTC

    ++ Good job improving that part on your own...

    Now look at what your original button's sub does: it assigned a new, empty hashref to the $ref_hash variable (as AM pointed out by printing multiple addresses when assigning the variable to multiple empty hashrefs: {}). Your updated one is an improvement, because it's accessing the original memory, rather than creating a new memory space. But you're deleting the keys and their values, rather than keeping the keys and just clearing the values.

    update: strike out something that might not be accurate. But your second code was still an improvement, because you learned you needed to de-reference the hashref, rather than assigning a new empty hashref {}

[reply]
[d/l]

      BTW: many monks will recommend use warnings; use strict;: this would have shown your original \$ref_hash{'VM-1'} issue at compile-time.

      edit: ... and many consider a more readable de-referencing for a hashref to be \$ref_hash->{'VM-1'} instead of \$$ref_hash{'VM-1'} (I knew I wanted to say two things, but when I replied to myself, I couldn't recall the second.)

[reply]
[d/l]
[select]

        Thanks for the reply. In the production code I do use strict & warnings. Should have in the test program too. Oops. AH! Excellent! I am clearing the whole hash. Duh! Thanks so much. And thanks for the tip. Big thanks!! ;-) For completeness, the new code works.

        use Tk;
use strict;
use warnings;

require Tk::Entry;
require Tk::Button;

my $mw = MainWindow->new();

my %work = (
    "VM-1" => "da923",
    "VM-2" => "dz427");

main_display(\%work);

MainLoop;

# -----------------------------------------------------
sub main_display {
    my $ref_hash = shift(@_);

    my $lab1 = $mw->Label(-textvariable => \$ref_hash->{'VM-1'},
                                            -relief => 'sunken',
                                            -width => 10,
                                            )->pack();
    my $lab2 = $mw->Label(-textvariable => \$ref_hash->{'VM-2'},
                                            -relief => 'sunken',
                                            -width => 10,
                                                )->pack();
    my $but = $mw->Button(-text=>'clear', -command=> [sub{
                                          $ref_hash->{'VM-1'} = " ";
                                          $ref_hash->{'VM-2'} = " ";
                                          $mw -> update;
                                           }] )->pack();

}

        [download]
[reply]
[d/l]
Re^4: Perl Tk label references
by Marshall (Canon) on Nov 10, 2016 at 22:52 UTC
    You created references to a couple of hash keys when you made the labels. If you later assign the $ref_hash variable to point to a "brand new" empty hash, that won't affect the label text locations. As far as Perl is concerned, those memory locations are still in use and unchanged. You could just change the value of the label keys to "" as shown below. 
    use Tk;

use strict;
use warnings;
use Data::Dumper;

my $mw = MainWindow->new();

my %work = (
    "VM-1" => "da923",
    "VM-2" => "dz427");

main_display(\%work);

MainLoop;

# -----------------------------------------------------
sub main_display {
    my $ref_hash = shift(@_);

    my $lab1 = $mw->Label(-textvariable => \$ref_hash->{'VM-1'},
                                            -relief => 'sunken',
                                            -width => 10,
                                            )->pack();
    my $lab2 = $mw->Label(-textvariable => \$ref_hash->{'VM-2'},
                                            -relief => 'sunken',
                                            -width => 10,
                                                )->pack();
    my $but = $mw->Button(-text=>'clear', -command=> sub{
                                          $ref_hash->{'VM-1'}="";
                                          $ref_hash->{'VM-2'}="";
                                          $mw -> update;
                                           } )->pack();

}

    [download]
[reply]
[d/l]

In Section Seekers of Perl Wisdom