It cannot match because the pattern expects \d+fish , which is not present in your string.

Maybe you want an additional .* after the \d+ ?

Thank you Corion. That was slightly embarrassing. :)

Hello Sarah,

This may sound like heresy, but actually you don’t need any lookaround assertions here. Building on the insights from other monks above, but removing the lookarounds and instead adding capturing parentheses:

 0:24 >perl -wE "my $s = qq[dogcat\n42\nbirdfish]; say qq[\nAh! The me
+aning of life is $1!] if $s =~ /dog.*?(\d+).*fish/s;"

Ah! The meaning of life is 42!

 0:25 >
[download]

Lookarounds are documented in perlre#Extended-Patterns. In particular:

Lookaround assertions are zero-width patterns which match a specific pattern without including it in $&. (Emphasis added)

Unless you need to exclude the pattern from $&, you probably don’t need positive lookaround assertions. (Negative lookarounds are a different matter.)

Hope that’s of interest,

G'day Sarah,

There's nothing wrong with either assertion. The apparent problem occurs because the first '.*' matches 'cat' and all the whitespace that follows it but nothing matches 'bird' and all the whitespace that precedes it.

Here's a simplified example of what you're currently doing:

$ perl -E 'say("X\n\t99\n\tY" =~ /(?<=X).*\d+(?=Y)/s ? 1 : 0)'
0
[download]

Here's how you might fix that:

$ perl -E 'say("X\n\t99\n\tY" =~ /(?<=X).*\d+.*(?=Y)/s ? 1 : 0)'
1
[download]

I'd also suggest you take a look at "perlre: Modifiers": note I only used 's'; the 'gxi' are not needed.

In addition to those pointed out by Corion and kcott, there's another little problem with the OPed regex. The first  .* assertion "consumes" all but one of the  \d digits available for  \d+ to match, giving a wrong answer to the question of Life, the Universe and Everything:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my $s = qq{DoGcat\n    42\n    birdfIsH};
 dd $s;
 print qq{<<$s>>};
 ;;
 print qq{LUE == '$1'} if $s =~ /(?<=dog) .* (\d+) .* (?=fish)/sxi;
"
"DoGcat\n    42\n    birdfIsH"

<<DoGcat
    42
    birdfIsH>>
LUE == '2'
[download]

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my $s = qq{DoGcat\n    42\n    birdfIsH};
 dd $s;
 print qq{<<$s>>};
 ;;
 print qq{LUE == '$1'} if $s =~ /(?<=dog) .*? (\d+) .* (?=fish)/sxi;
"
"DoGcat\n    42\n    birdfIsH"

<<DoGcat
    42
    birdfIsH>>
LUE == '42'
[download]

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my $s = qq{DoGcat\n    42\n    birdfIsH};
 dd $s;
 print qq{<<$s>>};
 ;;
 print qq{LUE == '$1'} if $s =~ /(?<=dog) \D* (\d+) .* (?=fish)/sxi;
"
"DoGcat\n    42\n    birdfIsH"

<<DoGcat
    42
    birdfIsH>>
LUE == '42'
[download]