in reply to How to restart a while loop that is iterating through each line of a file?

This kind of "for" loop: for (my $i=0; $i<=33; $i++) is not common in Perl. Try this: 
#!/usr/bin/perl
use strict;
use warnings;

my $filename = '16lines.txt';

open (INFILE, '<', $filename) or die
   "unable to read the file with 16+ lines $!";
   
my @lines = <INFILE>; #read all lines into an array

for my $file_no (0..33) #total 34 files?? Really? Maybe 0..31?
{
   open (my $fh, ">", "$filename$file_no.vcf") or die
      "problem opening $filename$file_no.vcf Oops $!";

   print $fh grep{defined}@lines[0..15];
   # the grep on defined lines is in case there are less
   # 16 lines in the input file. I am sure there are other
   # with perhaps split() to accomplish the same thing.
}

[download]

Replies are listed 'Best First'.
Re^2: How to restart a while loop that is iterating through each line of a file?
by Laurent_R (Canon) on Nov 28, 2016 at 23:32 UTC 
        for my $file_no (0..33) #total 34 files??

    [download]
    Yes, I asked myself the same question, but the original post says 34 different files.
[reply]
[d/l]
Re^2: How to restart a while loop that is iterating through each line of a file?
by cookersjs (Acolyte) on Nov 29, 2016 at 14:28 UTC
    I have a large file (~3.4 million lines) that I am trying to break into 100,000 line chunks. The file header is needed for all of the smaller files, which is why I wanted the first 16 lines populated over 34 files.

    Thanks for the suggestions monks! -cookersjs
[reply]
      Ok, I think I see what you are trying to do. Here is one way of many to code this sort of thing: 
      #!usr/bin/perl
use strict;
use warnings;

my $nHeaderLines = 2;
my $nDataLinesPerFile = 4;

my @header;

# the "Big File" is the DATA segment below,
# maybe millions of lines...

for (1..$nHeaderLines) # read header lines from big file
{
   my $header_line = <DATA>;
   push @header, $header_line;
}

# divide the big file data into smaller files,
# each with the initial header...

my $nFile = 0;
my $fileNameBase = "SmallerFile";
my $nDataLine = 99999;

my $line;
while ($nDataLine++, defined ($line = <DATA>))
{
   if ($nDataLine > $nDataLinesPerFile) # start new file
   {
       $nFile++;
       my $name = "$fileNameBase$nFile.txt";
       open (OUT, '>', "./$name") or die "$!";
       print OUT @header;
       $nDataLine=1;
   }
   print OUT $line;
}

print "Program Done!\n";

__DATA__
Header 1
Header 2
data 1
data 2
data 3
data 4
data 5
data 6
data 7
data 8
data 9

      [download]
      PS: This code has no advance knowledge of how many smaller files will be created. Nothing like "34 files" is hard coded.
      The code creates "as many files as are needed". In the case above, there are 3 files. data lines 1,2,3,4 in one file, data lines 5,6,7,8 in another and the last 9th data line in a third file.
[reply]
[d/l]

In Section Seekers of Perl Wisdom