So, I initially tried Stevieb's suggestion. It created the zip files, but there were no files inside the zip. So, I started playing. Again, I'm getting the zip files created, with the correct names, but there are no files inside the zips. Here is the latest attempt that I made at this:

use strict;
use warnings ‘all’;
use File::Copy::Recursive;
use Archive::Zip;
use constant AZ_OK =>0;
use File::Basename;
use File::Find::Rule;

my $mkvingestdir = “//nas/data/nonops/common/engine/ingest/sim/mkv”;
my $mkvingestdest = “//nas/shared/group/test/mkv/ingest”;

my @dirs = File::Find::Rule->directory()
                           ->in($mkvingestdir);

my @files;

foreach my $dir (@dirs) {
     @files = glob "*.eap";
     my $mkvingestzip = Archive::Zip->new();
     foreach $_ (@files) {
     $mkvingestzip->addFile($_);
     }
     my $name = basename $dir;
     if ($mkvingestzip->writeToFileNamed("$mkvingestdest/${name}.zip")
+ != AZ_OK) {
     print "Error in archive creation\n";
     next;
     }
     print "Archive created successfully!\n";
}
[download]

foreach my $dir (@dirs) {
     @files = glob "*.eap";
     my $mkvingestzip = Archive::Zip->new();
     foreach $_ (@files) {
     $mkvingestzip->addFile($_);
     }
[download]

I think that your problem here is that you are performing the glob in the $CWD which is not $dir and therefore it isn't matching. You could confirm this by adding diagnostic print statements like this:

foreach my $dir (@dirs) {
     print "Now processing dir $dir\n";
     @files = glob "*.eap";
     my $mkvingestzip = Archive::Zip->new();
     foreach $_ (@files) {
         print "Adding file $_\n";
         $mkvingestzip->addFile($_);
     }
[download]

You will likely see the "dir" diagnostics but no "file" ones. In that case you'll need either to chdir inside the outer loop or else prepend the path to the glob argument.

Printing diagnostics like this is item number 2 on the Basic debugging checklist.

You should check what's actually in @files. Not just for filenames but also whether they exist and (perhaps also) are of the expected size: see the built-in "File Test Operators".

I suspect you probably want to glob "$dir/*.eap". With your posted code, you're only looking for "*.eap" in the current directory. Look for other places where you may be referencing the current directory instead of $dir.

Two other minor points: (1) I wouldn't declare @files globally; (2) foreach and for are synonymous.

Putting all those points together, instead of:

my @files;

foreach my $dir (@dirs) {
     @files = glob "*.eap";
     ...
[download]

I probably would have written something closer to:

for my $dir (@dirs) {
    my @files = glob "$dir/*.eap";
    ...
[download]

For the inner loop, $_ is the default. Adding it the way you have (foreach $_ (@files) { ...) makes me, and quite possibly others, wonder if you perhaps had some other intention, e.g. a lexical 'my $_' (which should be avoided anyway - see below). One of these two forms would be more normal (and won't raise eyebrows):

for (@files) { ...
[download]

for my $file (@files) { ...
[download]

[Use foreach, instead of for, if you want to. It's really just extra (and unnecessary) typing. As stated earlier, the two are synonymous.]

Using a consistent style of indentation will make your code easier to read and less prone to errors. The choice of coding style is often a very personal one: choose whatever you want. See perlstyle if you want some tips on this.

Finally, and only because I mentioned it passing above, lexical $_ should be avoided. Here's its history:

• Introduced in v5.10.0: "perl5100delta: Lexical $_"
• Made experimental in v5.18.0: "perl5180delta: Lexical $_ is now experimental"
• Removed in v5.24.0: "perldelta: Lexical $_ has been removed"

— Ken

As hippo and kcott have pointed out, I was using glob incorrectly.

That's what I get for not fully following through to ensure everything did what it was supposed to ;)