Your constructor sets time in terms of localtime. Your half-hour calcuation subtracts a half hour from the object that was based on localtime. Your $oldtime object is constructed using strptime, and is not setting a timezone offset.

You can see this in action by adding the following lines:

print "\$ctime tzoffset:   ", $ctime->tzoffset, "\n";
print "\$halfago tzoffset: ", $halfago->tzoffset, "\n";
print "\$oldtime tzoffset: ", $oldtime->tzoffset, "\n";
[download]

which will produce output along the line of:

$ctime tzoffset:   -25200
$halfago tzoffset: -25200
$oldtime tzoffset: 0
[download]

(...except that the offsets will be in your own localtime, not mine.)

You might be able to set the $oldtime->tzoffset($some_value), or preferably by providing a %Z or %z field to strptime.

Replacing your time with one here which should trigger the if branch (rather than the else) I am unable to reproduce your findings.

$ perl 1178137.pl 
The current time is Mon Dec 19 23:40:37 2016
The old time is Mon Dec 19 23:31:00 2016
Half an hour ago is Mon Dec 19 23:10:37 2016
Old time is within a half hour
[download]

If you think you have timezone (or DST) problems it is always best to output the epoch times as a diagnostic aid. I suggest you give that a try.

Strange... Or more likely I don't understand what is going on here, being a noob. Your suggestion about using the epochs helped me at least figure out a way around my problem. If I add:

$oldtime = $oldtime - $ctime->tzoffset;
[download]

I get the desired results, although my statement

print "The old time is $oldtime\n";
[download]

Then prints a formatted time 6 hours in the future. I needed to update that to

print "The old time is ", $oldtime + $ctime->tzoffset, "\n";
[download]

To get it to print the correct time. That isn't a great concern as I actually won't ever be using the print statements, only the calculations, in the bigger script I am retrofitting. Still, it shows I am missing something basic in how this all works and that concerns me.

Note: where I am tzoffset is -21600 (-6 hours, CST).

Hi sjessie,

As hippo and davido have already identified, the issue is with time zones. Personally, I like to use the DateTime module since it includes a lot of functionality, including time zones. (Because of that it's a little more heavyweight, but that should only be noticeable if your script does a lot of date/time calculations, so personally I just throw all of my date/time stuff at the DateTime suite because it can handle it all, and only consider using other modules as an optimization if necessary.)

Anyway, here are two methods that work. Note that this handles time zones properly, for example try changing the first "America/New_York" to "America/Chicago". Update: Just to emphasize this, the key is that all the DateTime objects involved in the calculations and comparisons need to have their time zones set properly.

use warnings;
use strict;

use DateTime;
use DateTime::Format::Strptime;

my $old_str = 'Dec 19 17:01:00 2016';
# normally, $now = DateTime->now
my $now = DateTime->new(year=>2016,month=>12,day=>19,
    hour=>17,minute=>7,second=>6,time_zone=>'America/New_York');
print "now=", $now->strftime('%Y-%m-%d-%H-%M-%S %Z'), "\n";

my $strp = DateTime::Format::Strptime->new(
    on_error=>'croak', pattern => '%b %d %T %Y',
    time_zone=>'America/New_York' );
my $old = $strp->parse_datetime($old_str);
print "old=", $old->strftime('%Y-%m-%d-%H-%M-%S %Z'), "\n";

# approach one: difference
my $diff_sec = $now->subtract_datetime_absolute($old)
    ->in_units('seconds');
print "diff_sec: $diff_sec (",
    sprintf("%.1f",$diff_sec/60), " minutes)\n";

# approach two: compare to another DateTime
my $halfago = $now->clone->subtract(minutes=>30);
print "halfago=", $halfago->strftime('%Y-%m-%d-%H-%M-%S %Z'), "\n";
# note comparators are overloaded for DateTime objects
print "halfago ", ($halfago>$old?'>':'<='), " old\n";
[download]

Hope this helps,
-- Hauke D

Wohoo! Thanks for helping out a goofy noob, Monks! You guys rock! I hadn't really touched Perl (I know, blasphemy) for the last 10 years or so, so I really appreciate you all getting me back on the road. It is coming back to me. Slowly.