If I were going to do what you say, I might write something like:

#!/usr/bin/perl
use strict;
use warnings;
use 5.10.0;

my %count;

while (<DATA>) {
    if (/^(\S+)\s+([A-Z])$/) {
        $count{$1}{$2}++;
    } else {
        warn "Regular expression failed on $_";
    }
}

for my $name (sort keys %count) {
    if (exists $count{$name}{Z}) {
        say "$name $count{$name}{Z}"
    }
}

__DATA__
Tommy Z
Tommy Z
Chris Z
Chris B
Chris Z
Jake Z
Jake Y
[download]

Important elements are keeping the line parsing code tight and minimizing the global memory footprint. Post more realistic data, and we can help refine regular expressions. Also note you are optimizing without profiling. In your circumstance, I will usually grab the first 1000 lines, and test my code with Devel::NYTProf to figure out if I'm doing something silly.

If you run something like the above on your file, the code should take about as long as just running

#!/usr/bin/perl
use strict;
use warnings;
use 5.10.0;

my $count;
while (<DATA>) {
    $count++
}
say $count;
[download]

If just counting lines in this way is too slow for your need, you'll need to use the window technique I and LanX have mentioned.