Beyond that, there's no need to stringify variables. If you want to set $exact_file to $junk_file, just do it. (If you're relying on overloaded stringification, it may be more clear to concatenate the assignee with the empty string. Luckily, you're not doing this, so don't worry about it. ;)

Other things... you're reading a file linewise, pushing each onto an array, and then comparing just the first two lines. Why not just read two lines?

Beyond that, it is good style to avoid indirect method calls (CGI::Cookie->fetch is much preferable to fetch CGI::Cookie), and calling subs with a leading ampersand and no argument lists *will* eventually cause you debugging grief. Use parens. Then drop the leading ampersand, as it's unnecessary.

I don't get why you're maintaining a lot of information that you're not going to use. That's a *lot* of variable declarations in there, some of which aren't needed through the whole routine. There's also a lot that can make your code more compact and elegant. Case in point:

my %cookies; 
#lots more code
if (%cookies = fetch CGI::Cookie) {
[download]

Can be elegantly compacted into

if ( my %cookies = fetch CGI::Cookie ) {
}
[download]

( warning: these aren't entirely equivalent, but since you're only interested in %cookies within that if block, you shouldn't notice the difference here.)

Note also that

if (CONDITION1) { 
  if (CONDITION2) { 
  }
}
[download]

is equivalent to

if (CONDITION1 && CONDITION2) {
}
[download]

IMO, the second is much easier to follow.

The main thing you're looking for: you want to stop once you've found the right line in the "members" file. So use last -- not break ( some C coder musta misremembered) -- to break out of the loop. It's not really use strict that causes the complaint, it's the fact that the parser doesn't recognize break as a keyword, and so thinks it's a bareword, which causes strict to complain. In reality, it's a syntax error.

while( my($login, $junkfile) = split /\|!!\|, <FH>) {
 if ($login eq $id) {
     chomp $junkfile;
     $exact_match = $junkfile;
     last;
 }
}
[download]

perl -e 'print "How sweet does a rose smell? "; chomp ($n = <STDIN>); 
+$rose = "smells sweet to degree $n"; *other_name = *rose; print "$oth
+er_name\n"'
[download]

What the others said :)

Separate the HTML output from the logic: this code has the main effect of returning a userid, and the side effect of outputing the HTML header. At some point, you won't want to do the two things together.

Why not return undef, or '' as the not logged in value? I hope those will never match a valid userid, and also allows you to write:

my $userid=getuserid or castigate_user;
[download]

Use if as a statement modifier, rather than as a test in it's own right, then the code becomes more linear, and easier to read:

sub get_userid {
  my $member_dir = "../../Members/";
  my $member_file ="memberslist.cgi";

  return undef unless my %cookies = fetch CGI::Cookie;
  return undef unless $cookies{'UserName'};
  return undef unless $cookies{'Password'};

  my $id = $cookies{'UserName'}->value;
  my $password =  $cookies{'Password'}->value;

  my $exact_file;
  $file = "$member_dir/$member_file";
  open (FH, "< $file") or die "Could not open $file: $!";
  while (<FH>){
    chomp;
    my ($login, $junk_file) = split(/|!!|/);
    if ($login eq $id) {
      $exact_file=$junk_file;
      last;
    }
  }
  close FH;
  return undef unless $exact_file;

  $file ="$member_dir/$exact_file.cgi";
  open (FH, "< $file") or die "Could not open $file";
  my @user_list=(<FH>, <FH>);
  close FH;

  return undef unless $user_list[0] eq $id and
         $user_list[1] eq $password;

  return $id;
}
[download]

Finally, do you really need to have an arbitarilly named password file for every single user? Why not just store the password directly in the members.cgi file?

I do appreciate the suggestions. I like what you have much more than what I had.

As to your last question that is just what UBB does. That is not something that I do. It is something that seems slow for my use, but I have to work with what they have given me. Again, Thanks.

My code as stands is now the following taking information from all of the above users. Thanks to those. This works and the subroutine will return either undef or the users id.

#!d:\perl\bin\perl.exe -w
use strict;
use CGI;
use CGI::Cookie;

print "Content-type:text/html\n\n";
my $user = get_userid();
print "UNDEF" if($user eq undef);
print "<p>whoa whoa whao $user" if($user ne undef);

sub get_userid {
  my $member_dir = "../../Members/";
  my $member_file ="memberslist.cgi";

  return undef unless my %cookies = CGI::Cookie->fetch;
  return undef unless $cookies{'UserName'} and $cookies{'Password'};

  my $id = $cookies{'UserName'}->value;
  my $password =  $cookies{'Password'}->value;

  my $exact_file;
  my $file = "$member_dir/$member_file";
  open (FH, "< $file") or die "Could not open $file: $!";
  while( my($login, $junkfile) = split /\|!!\|/, <FH>) {
    if ($login eq $id) {
       chomp $junkfile;
       $exact_file = $junkfile;
       last;
    }
  }

  close FH;

  return undef unless $exact_file;

  $file ="$member_dir/$exact_file.cgi";
  open (FH, "< $file") or die "Could not open $file";
  chomp (my @user_list= (<FH>, <FH>));
  close FH;
  return undef unless $user_list[0] eq $id and
         $user_list[1] eq $password;

  return $id;
}
[download]

LeGo

D'oh! The point of undef is that it evaluates to false in logic statements (see the compound statement section of perlsyn). So you don't need to explicitely test against it:

my $user = get_userid();
print "UNDEF" unless $user;
print "<p>whoa whoa whao $user" if $user;
[download]

(oh, you don't need to bracket the conditions, when they're modifiers, and unless is the equivalent of "if not")