# take IP4 address string
my $IP_str = '192.0.2.4';

# convert the numbers to hex
my @IP4_a = map { sprintf("%02x", $_) } split(/\./,$IP_str);

# embed these hex numbers in the IPv6 template
my $R = sprintf("2002:%s%s:%s%s::/48", @IP4_a);

# output the result
die  "($R)";
[download]

something like that?

sub ipv4_6to4{
  return sprintf("2002:%s%s:%s%s::/48", map {sprintf("%02x",$_)} split
+(/\./,$_[0]));
}
[download]

Nice work. I've just had cause to do the reverse so here is the sub I wrote in case it is useful to someone else.

use strict;
use warnings;
use Regexp::Common 'net';
use Carp;

sub to_ipv4 {
    my $v6 = shift;

    unless ($v6 =~ /$RE{net}{IPv6}{-keep}/) {
        carp "'$v6' is not a valid IPv6 address";
        return;
    }

    unless ($2 eq '2002') {
        carp "'$v6' is not a 6to4 IPv6 address";
        return;
    };

    my @octets;
    my @parts = ($4, $3);
    for my $part (@parts) {
        unshift @octets, hex substr ($part, -2, 2, '') for 1, 2;
    }
    return join '.', @octets;
}

# Example usage
my $v4 = to_ipv4 ($ARGV[0]) // 'invalid';
print "$v4\n";
[download]

---

🦛

sub ipv4_6to4 works like a charm. Thanks a ton. :)

What problem are you trying to solve?

Are you trying to add IPv6 connectivity to an application that only speaks IPv4? Are you trying to add IPv4 connectivity to an application that only speaks IPv6?

Are you trying to find the IPv4 address of a user that connects to your application using IPv6? Are you trying to find the IPv6 address of a user that connects to your application via IPv4?

If you can show us a short, self-contained example (in Perl) of what you have and what you need, then we can likely give you much better advice.