you don't want to operate on an array but a code-block

Would you accept something like the following as sufficiently equivalent?

sub qre(&;@) {
  my $block = shift;
  my $str = $block->(@_);
  return qr/$str/;
}
[download]

(not tested)

udpate

some functional code:

use Data::Dump;

sub qre(&;@) {
  my $block = shift;
  my $str = $block->(@_);
  return qr/$str/;
}

sub ored {
   return join '|', map {quotemeta} @_
}

sub oredraw {
   return join '|', @_
}

my @strings = qw/. | %/ ;


dd qre {join '|', map {quotemeta} @strings };

dd qre \&ored, @strings;

dd qre \&oredraw, @strings;
[download]

Hi LanX,

sub qre(&;@) {
  my $block = shift;
  my $str = $block->(@_);
  return qr/$str/;
}
[download]

Thanks, that's an excellent piece of inspiration! Just to take that idea a little further and add support for /i and the like:

sub qre (&;$) {
    my $re = shift->();
    eval 'qr/$re/'.(shift//'') || die $@
}

my $regex = qre{ join '|', qw/foo bar/ }'i';
print "$regex\n";

__END__

(?^i:foo|bar)
[download]

Not that I'm going to start using this right away, for now this is just to satisfy my curiosity ;-)

Thanks,
-- Hauke D

One extra tweak to the prototype would allow you to add trailing modifiers without requiring the pesky quotes around them:

sub qre (&;*) {
    my $re = shift->();
    eval 'qr/$re/'.(shift//'') || die $@
}

my $regex = qre{ join '|', qw/foo bar/ }i;

print "$regex\n";
__END__
[download]

or, from Perl 5.20 onwards:

sub qre :prototype(&;*) {
    my $re = shift->();
    eval 'qr/$re/'.(shift//'') || die $@
}                 

my $regex = qre{ join '|', qw/foo bar/ }i;

print "$regex\n";
[download]

Damian