G'day 3dbc,

Welcome back!

I don't have access to your platform (Win32::* modules, "MSWord", etc.) but, as I see no one has replied in over eight hours, here's at least a technique you could use, to split your replacement string into smaller parts, and then do multiple replacements.

#!/usr/bin/env perl

use strict;
use warnings;
use constant {
    MAX_STR_LEN => 5,
    TOKEN => '#T#',
};  

use Test::More;

my @tests = (
    ['#T#', 'abc', 'abc'],
    ['#T#', 'abcd', 'abcd'],
    ['#T#', 'abcde', 'abcde'],
    ['#T#', 'abcdef', 'abcdef'],
    ['#T#', 'abcdefg', 'abcdefg'],
    ['#T#', 'abcdefghijklm', 'abcdefghijklm'],
    ['', 'abcdefghijklm', ''],
    ['xyz', 'abcdefghijklm', 'xyz'],
    ['MNO #T# PQR', 'abcdefghijklm', 'MNO abcdefghijklm PQR'],
    ['MNO#T# PQR', 'abcdefghijklm', 'MNOabcdefghijklm PQR'],
    ['MNO #T#PQR', 'abcdefghijklm', 'MNO abcdefghijklmPQR'],
    ['MNO#T#PQR', 'abcdefghijklm', 'MNOabcdefghijklmPQR'],
    ['MNO##T##PQR', 'abcdefghijklm', 'MNO#abcdefghijklm#PQR'],
);

plan tests => scalar @tests;

for (@tests) {
    my ($target, $replace, $expect) = @$_;
    my $newstr = $target;
    my @replacements;

    if (index($newstr, TOKEN) != -1) {
        for (my $pos = 0; $pos < length $replace; $pos += MAX_STR_LEN)
+ {
            push @replacements, substr $replace, $pos, MAX_STR_LEN;
        }

        for my $replacement (@replacements) {
            substr $newstr, index($newstr, TOKEN), 0, $replacement;
        }

        substr $newstr, index($newstr, TOKEN), length TOKEN, '';
    }

    is($newstr, $expect, "'$target' -> '$expect'");
}
[download]

Output:

1..13
ok 1 - '\#T\#' -> 'abc'
ok 2 - '\#T\#' -> 'abcd'
ok 3 - '\#T\#' -> 'abcde'
ok 4 - '\#T\#' -> 'abcdef'
ok 5 - '\#T\#' -> 'abcdefg'
ok 6 - '\#T\#' -> 'abcdefghijklm'
ok 7 - '' -> ''
ok 8 - 'xyz' -> 'xyz'
ok 9 - 'MNO \#T\# PQR' -> 'MNO abcdefghijklm PQR'
ok 10 - 'MNO\#T\# PQR' -> 'MNOabcdefghijklm PQR'
ok 11 - 'MNO \#T\#PQR' -> 'MNO abcdefghijklmPQR'
ok 12 - 'MNO\#T\#PQR' -> 'MNOabcdefghijklmPQR'
ok 13 - 'MNO\#\#T\#\#PQR' -> 'MNO\#abcdefghijklm\#PQR'
[download]

You could search for and delete the token then insert the new text

#!perl
use strict;
use Win32::OLE;
use Win32::OLE::Const 'Microsoft Word';
$Win32::OLE::Warn = 3;
my $word = Win32::OLE->new('Word.Application', 'Quit') or die;
$word->{Visible} = 1;
$word->{DisplayAlerts} = 0;  

my $doc = $word->Documents->Open({FileName => "c:/temp/Word.doc"});
my $sel = $word->Selection;
$sel->Find->{Forward}        = 1;
$sel->Find->{MatchWholeWord} = 1;
  
for my $n (1..2){
  $sel->Find->{Text} = '##TOKEN'.$n.'##';
  $sel->Find->Execute;
  $sel->Delete;
  $sel->InsertAfter("($n) This is line 1 of some new text that is more
+ than 255 characters.
This is line 2 of some new text that is more than 255 characters.
This is line 3 of some new text that is more than 255 characters.
This is line 4 of some new text that is more than 255 characters.
This is line 5 of some new text that is more than 255 characters.
This is line 6 of some new text that is more than 255 characters.
This is line 7 of some new text that is more than 255 characters.
This is line 8 of some new text that is more than 255 characters.");
  $sel->MoveDown({Count=>1});
};
$doc->SaveAs({FileName => 'c:/temp/Word1.doc'});
$doc->Close();
[download]

Thanks so much Monks for welcoming me back. Couldn't resist using my old account because I'm only 100 points away from being titled a Monk! I think this last post is exactly what I was looking for... I'm not sure you can do multiple replacements with that win32 ole method? Giving it a shot now. THANK YOU

Also wanted to provide the error message returned in case anyone is searching for this on this site or through google by the error code.



Win32::OLE(0.1712) error 0x80020009: "Exception occurred"
    in PROPERTYPUT "Text" at evolveIT2.pl line 193.
OLE exception from "Microsoft Word": String parameter too long.
[download]