Hi Anonymous,

send_1 is a good example of passing named parameters to a sub with a hash. (Update: Technically, what is happening is that the subroutine is passed a flat list of key+value pairs, since using the => operator doesn't automatically make something a hash. However, once you say my (%args) = @_;, that flat list of key+value pairs is stored in a hash.)

However, in send_2, in the call of the sub (send_2( { name => ... } )) what you are passing the sub is a reference to an anonymous hash, whereas the implementation of sub send_2 is expecting a flat list of positional parameters. The correct way to call the sub send_2 in your example code would be:

send_2( $name, $pic, 'test' );
[download]

If instead you wanted to implement arguments passed in as a hash reference, you'd need to rewrite sub send_2 like this (untested):

sub send_2 {
    my ($args) = @_;
    my $name = $args->{ name } || '';
    my $filehandle = $args->{ filehandle } || '';
    my $id = $args->{ id } || '';
}
[download]

Update: See "Use Rule 2" in perlreftut for an explanation of the $args->{...} syntax. Note that it could also be written $$args{...}.

Hope this helps,
-- Hauke D

sub send_2 {
    my $args = shift;
    my $name = $args->{name} || '';   
}
[download]

• perldsc

You can avoid it, but it is clunky:

use 5.010;

sub send_3{
  my ($h) = @_;

  # 'fix' if broken parameters
  unless(ref($h) eq 'HASH'){
    my %X = @_;
    $h = \%X;
  }

  # set default values
  $h->{foo} //='default';

  # iterate over parameters
  for my $key (keys %$h){
    say "$key ~> $h->{$key}"
  }
}


send_3( {"foo"=>42, "bar"=>'code'});
send_3( "baz"=>11, "zab"=>'dong');
[download]

Which yields:

fbrm@monastery:~/CODE/PERL/monks$ perl x
foo ~> 42
bar ~> code
zab ~> dong
foo ~> default
baz ~> 11
[download]

Note that starting from perl 5.10, you can use the "//=" operator to test if the variable is defined, and not just non-zero. (Imagine the call send_3(foo=>"0", bar=>"cool"), which using the above would yield "default cool", which might not be what you wanted. Using the //= operator it would yield "0 cool").

use Data::Dumper;

sub send_2 {
    my %args = (name => 'default',
                filehandle => 'default',
                id => 'default',
                %{ +shift }
                );
                
    print Dumper \%args;
}

send_2( {name => 'Tom', id => 'IT001'} );
send_2( {name => 'Mary', filehandle => 'ARGV', id => 'foo'} );
[download]

$VAR1 = {
          'filehandle' => 'default',
          'name' => 'Tom',
          'id' => 'IT001'
        };
$VAR1 = {
          'filehandle' => 'ARGV',
          'name' => 'Mary',
          'id' => 'foo'
        };
[download]

(You could have just as easily have a default == the empty string ('') or whatever you want as a default.