Push the matching records to an array and sort them before outputting. For example

#!perl
use strict;
use Data::Dump 'pp';

# build key words hash
print "\n Starting success message flow\n\n";
my $kwhashref = get_keywords('Success_MessageFlow.txt');
#pp $kwhashref;

# create regex
my $match = join '|',map{quotemeta} keys %$kwhashref;
my $re = qr/$match/;
#print $re;

# get list of files in current directory
my @files = <main_log*>;

# process records
#12-26 13:35:05.623529   236   578 D Bye Sample Bye Sample
my @output = ();
foreach my $file (@files) {
  print "\n Processing with file $file \n";
  open my $fh, '<', $file or die $!;
  my $count = 0;
  while (<$fh>){
    ++$count;
    # match any keyword
    if (/($re)/){
      my $kw = $1;
      push @output, [$kw,$file,$count,$_];
    }
  }
  close $fh;
}

# sort by record timestamp
@output = sort { $a->[3] cmp $b->[3]} @output;
#pp \@output;

# output
my $outfile = 'IMS_Reg_Message_Flow.txt';
print "Check the output generated In file $outfile\n";
open my $fh_out, '>', $outfile or die "$!";
for (@output){
  my $kw = $_->[0];
  if ( defined $kwhashref->{$kw} ){
    print $fh_out "\n*******$kwhashref->{$kw}*******\n";
  }
  printf $fh_out '%s in file %s, line %d:%s'.$/, @$_;
}
close $fh_out;

# get keywords
sub get_keywords {
  my $infile = shift;
  my %keyword=();
  open( my $in,'<', $infile) or die $!;
  while (<$in>){
    if (/^(.*?)(#.*?#)*$/){
      $keyword{$1} = $2;
    }
  }
  close $in; 
  return \%keyword;
}
[download]

Hi,, Can I get the output Into respective file rather than Into single file e.g. If I am parsing keywords from main_log then output something like output_main_log & if I am parsing though main_log(2) then output generated In output_main_log(2)rather than In the single file to have more clarity ? Thanks

Move the output code inside the @files loop

foreach my $file (@files) {
  my @output = ();
  print "\n Processing with file $file \n";
  open my $fh, '<', $file or die $!;
  my $count = 0;
  while (<$fh>){
    ++$count;
    # match any keyword
    if (/($re)/){
      my $kw = $1;
      push @output, [$kw,$file,$count,$_];
    }
  }
  close $fh;

  # sort by record timestamp
  @output = sort { $a->[3] cmp $b->[3]} @output;
  #pp \@output;

  # output
  my $outfile = 'output_'.$file;
  print "Check the output generated In file $outfile\n";
  open my $fh_out, '>', $outfile or die "$!";
  for (@output){
    my $kw = $_->[0];
    if ( defined $kwhashref->{$kw} ){
      print $fh_out "\n*******$kwhashref->{$kw}*******\n";
    }
    printf $fh_out '%s in file %s, line %d:%s'.$/, @$_;
  }
  close $fh_out;
}
[download]

poj

You could build up another hash with the matches found, and sort by the timestamp before printing to your output file. See sort for documentation on how to create a custom sort subroutine.

Hope this helps!