use warnings;
use strict;

while (<DATA>) {
    s/(\d)_/$1:/;
    print;
}

__DATA__
V12345:name_test
V12345_name_test
[download]

Worked like a champ. Very much appreciated.

Something like this perhaps?

#!/usr/bin/env perl 
use strict;
use warnings;
use Test::More;

my @rows = (
        {
                have => 'V12345:name_test',
                want => 'V12345:name_test'
        },
        {
                have => 'V12345_name_test',
                want => 'V12345:name_test'
        },
);

plan tests => scalar @rows;

for my $row (@rows) {
        my $out = $row->{have};
        $out =~ s/(\d)_/$1:/;
        is ($out, $row->{want});
}
[download]

How well this regex works depends on how true your sample dataset is. You can amend @rows and the regex until you have covered all the possibilities you require. See also How to ask better questions using Test::More and sample data.

Addendum: I see that toolic has used precisely the same substitution in his answer while I was constructing this. That bodes well for it as a solution to your specific question.

The following works for the very limited test cases you've provided. Because I wasn't sure whether by "if there is a "_" after the numbers" you meant "immediately after the numbers", or just "somewhere after the numbers", I invented two more test cases, but I don't know if they represent what your strings actually look like. If you could provide more test cases, we could be of more help.

use warnings;
use strict;
use Test::More;

sub subst {
    my $x = shift;
    $x =~ s/\d+[^_:]*\K_/:/;
    return $x;
}

is subst("V12345_name_test"),  "V12345:name_test";
is subst("V12345:name_test"),  "V12345:name_test";
is subst("V12345x_name_test"), "V12345x:name_test";
is subst("V12345x:name_test"), "V12345x:name_test";
# ... more test cases needed here!

done_testing;
[download]

Update: Added the other two test cases. Added some more explanation.

Heelo ddrew78,

Something like that?

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my @array = ("V12345:name_test", "V12345_name_test");

my @final = ();
foreach my $str (@array) {
    if ($str =~ /[\w]+:/) {
    my @elements = split /:/, $str, 0;
    my $tmp = $elements[0] . "_" . $elements[1];
    push @final, $tmp;
    }
    next;
}

print Dumper \@final;

__END__

$ perl test_2.pl
$VAR1 = [
          'V12345_name_test'
        ];
[download]

There are other ways I am sure but just an idea.

Hope this helps.