G'day Tmms,

Welcome to the Monastery.

"I am fairly new at perl and I am struggling with references."

Take a look at "perlreftut - Perl references intro" for general information on references; it contains links to more detailed information - follow as needed.

For general information on data structures, see "perldsc - Perl data structures intro"; again, this has links to more detailed documentation.

The type of data structure you're attempting to create is called a Hash of Arrays (typically abbreviated to HoA). If you look at "Generation of a HASH OF ARRAYS" (in perldsc), the last line of the example code is pretty much what you're looking for.

So, working from just your example data, your code would look something like this:

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dump;

my %hash;

while (<DATA>) {
    chomp;
    my ($value, $key) = split /\t/;
    push @{$hash{$key}}, $value;
} 

dd \%hash;

__DATA__
Obi Wan Jedi
Yoda    Jedi
Count Dooku Sith
[download]

Output:

{ Jedi => ["Obi Wan", "Yoda"], Sith => ["Count Dooku"] }
[download]

While that works fine with your (ideal) example data, real world data throws up all sorts of nasty challenges. Whenever you're working with comma- (tab-, pipe-, whatever-) separated values, I recommend you use the Text::CSV module. If you also have Text::CSV_XS installed, it will run faster. This module has addressed these "nasty challenges": this is not a wheel you need to reinvent. In this instance, the while loop only needs one statement.

#!/usr/bin/env perl

use strict;
use warnings;

use Text::CSV;
use Data::Dump;

my %hash;

my $csv = Text::CSV::->new({sep_char => "\t"});

while (my $row = $csv->getline(\*DATA)) {
    push @{$hash{$row->[1]}}, $row->[0];
}

dd \%hash;

__DATA__
Obi Wan Jedi
Yoda    Jedi
Count Dooku Sith
[download]

Output (exactly the same as before):

{ Jedi => ["Obi Wan", "Yoda"], Sith => ["Count Dooku"] }
[download]

See also: Data::Dump (which provides the dd function) or use Data::Dumper (which is a core module).

Here is a self-contained solution that demonstrates the idioms.

This code uses "Autovivification" to avoid the issue you experienced - i.e. the same code handles both the case where the key is absent, and when present. Read all about it in perlref.

use strict;
use warnings;

my %team;

while (defined (my $line=<DATA>)){
    chomp $line; # Zap the newline
    my ($name,$affiliation) = split /\t/,$line;
    next unless $affiliation; # Avoid empty lines
    push @{ $team{$affiliation} }, $name;
}

# Print the results
for my $aff (sort keys %team){
    print $aff, " :\t",
          join(", ", sort @{ $team{$aff} }) , "\n";
}


__DATA__
Obi Wan    Jedi
Yoda    Jedi
Count Dooku    Sith
Darth Vader    Sith
Luke Skywalker    Jedi
[download]

Jedi :    Luke Skywalker, Obi Wan, Yoda
Sith :    Count Dooku, Darth Vader
[download]

Looks like each time you are overwriting the hash entry with a new one element array.

Please try to push instead

  push @{$hash{$affiliation}}, $name;

Depending on the Perl version you'd be allowed to leave the @{...} out. °

HTH :)

°) please forget, because (strangely) "Starting with Perl 5.14, an experimental feature allowed push to take a scalar expression. This experiment has been deemed unsuccessful, and was removed as of Perl 5.24."

Thank you for the replies. I will try the solutions and read the documents.