Re: one liner question

I'll put in my two cents worth. Use Tie::File to get an array and then reverse it before traversing it.

use warnings;
use strict;
use Tie::File;

tie my @filearray, 'Tie::File', 'backwards.log' or die "couldn't tie f
+ile $!\n";

foreach (reverse @filearray) {
    if (/received/) {
        printf "%s %s\n", (split)[0,1];
        last;
    }
}
[download]

Comment on Re: one liner question Select or Download Code

Replies are listed 'Best First'.
Re^2: one liner question by haukex (Archbishop) on Apr 21, 2017 at 15:01 UTC
Tie::File is a good idea. One disadvantage is that it'll have to scan the entire file once and use up some memory to store the offsets of all the lines in the file when it is determining the size of the array. I wondered if the optimization of `for (reverse @array)` (since Perl v5.8.6) also applies to tied arrays, and it turns out that it does: `{ package LoggedArray; use Tie::Array; our @ISA = ('Tie::StdArray'); sub TIEARRAY { bless [@_[1..$#_]], $_[0] } for my $sub (qw/ FETCHSIZE STORESIZE STORE FETCH CLEAR POP PUSH SHIFT UNSHIFT EXISTS DELETE SPLICE EXTEND /) { no strict 'refs'; *$sub = sub { my $self = shift; warn "$sub @_\n"; $self->${\"SUPER::$sub"}(@_); } } } tie my @array, 'LoggedArray', qw/one two three/; print "<$_>\n" for reverse @array; __END__ FETCHSIZE FETCH 2 <three> FETCH 1 <two> FETCH 0 <one>` [download]	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^2: one liner question
by haukex (Archbishop) on Apr 21, 2017 at 15:01 UTC

Tie::File is a good idea. One disadvantage is that it'll have to scan the entire file once and use up some memory to store the offsets of all the lines in the file when it is determining the size of the array. I wondered if the optimization of for (reverse @array) (since Perl v5.8.6) also applies to tied arrays, and it turns out that it does:

{
    package LoggedArray;
    use Tie::Array;
    our @ISA = ('Tie::StdArray');
    sub TIEARRAY { bless [@_[1..$#_]], $_[0] }
    for my $sub (qw/ FETCHSIZE STORESIZE STORE FETCH CLEAR
        POP PUSH SHIFT UNSHIFT EXISTS DELETE SPLICE EXTEND /) {
        no strict 'refs';
        *$sub = sub {
            my $self = shift;
            warn "$sub @_\n";
            $self->${\"SUPER::$sub"}(@_);
        }
    }
}
tie my @array, 'LoggedArray', qw/one two three/;
print "<$_>\n" for reverse @array;

__END__

FETCHSIZE 
FETCH 2
<three>
FETCH 1
<two>
FETCH 0
<one>
[download]

[reply]
[d/l]
[select]