Hello rinkish85,

I think the following does what you want:

use strict;
use warnings;
use feature 'say';

my @files =
(
    'log4perl.Advanced1999:06:56:12.General_Information.ErrorLog',
    'log4perl.Advanced1999:06:56:12CSS.General_Information-collector-2
+.ErrorLog',
    'log4perl.Advanced1999:06:56:12CSS.General_Information-collector-2
+.INVALID',
);

for (@files)
{
    if (/ ^ [\w_-]+ \. [\w:]+ \. [\w_-]+ \. ErrorLog $ /x)
    {
        s/ ^ ([\w_-]+) \. ([\w:]+) CSS \. /$1.$2./x;
        say;
    }
}
[download]

Output:

13:43 >perl 1783_SoPW.pl
log4perl.Advanced1999:06:56:12.General_Information.ErrorLog
log4perl.Advanced1999:06:56:12.General_Information-collector-2.ErrorLo
+g

13:43 >
[download]

See perlrecharclass.

Hope that helps,

Thank you so much.

for (@files)
{
    if (/ ^ [\w_-]+ \. [\w:]+ \. [\w_-]+ \. ErrorLog $ /x)
    {
        s/ ^ ([\w_-]+) \. ([\w:]+) CSS \. /$1.$2./x;
        say;
    }
}
[download]

Can i extend  s/ ^ ([\w_-]+) \. ([\w:]+) CSS \. /$1.$2./x; subsitution of CSS to [A-Z]. ?

Yes you can, but you need to add a quantifier. For example:

 s/ ^ ([\w_-]+) \. ([\w:]+) [A-Z]{3} \. /$1.$2./x;
[download]

or possibly:

 s/ ^ ([\w_-]+) \. ([\w:]+) [A-Z]+ \. /$1.$2./x;
[download]

But you might have to watch out that [A-Z]+ will not match some other uppercase letter(s) before in some other file names.

Are there any strings in your logfile array containing CSS which shouldn't be altered? If not, you could just go with

for (@filenames) {
    s/CSS//;
}

# or written with a statement modifier:
# s/CSS// for @filenames;
[download]

You could run the above code over your array and check for false positives, and extend the regular expression if so.

Since your strings are tokens concatenated with a dot, of which the last is always ErrorLog, you could anchor your regular expression at the end with $ and remove CSS from the token preceeding the last two:

for (@filenames) {
    s{           # substitute 
      CSS        # the string CSS 
      (          # and a capture consisting in
        \.       # a literal dot,
        [^\.]+   # any number of non-dots,
        \.       # another literal dot,
        ErrorLog # and the constant ErrorLog
      )          # (end of capture)
      $          # anchored at the end of the string
    }
    {$1}x;       # against the capture above
}
[download]

Or written more concisely with a terse explanation:

for (@filenames) {
    s/CSS(\.[^\.]+\.ErrorLog)$/$1/; # remove CSS from end of antepenul
+timate token
}
[download]

Perhaps more effective and faster, if you have only a few strings with CSS: look for CSS, if found, split, remove and join:

for (@filenames) {
    if (/CSS/) {
        my @t = split /\./;
        $t[-3] =~ s/CSS$//;
        $_ = join '.', @t;
    }
}
[download]

Thank you