You could have caught this yourself if you would have used strictand warnings:

#!/usr/bin/perl
use strict;
use warnings;

my @needles   = ("1-2 Steps", "5-7 Steps", "8-10 Steps", "catch");
my @haystacks = ("move 1-2 steps", "move 8-10 steps to hoist", "catch 
+the ball");

for my $needle (@needles) {
    my $found;

    for my $haystack (@haystacks) {
        if ($haystack =~ /\i\Q$needle\E\i/) {
            print "<br>";
            print "Found [$needle] in [$haystack]\n";
            print "</br>";
            $found++;
        }
    }

    if (!$found) {
    print "<br>";
    print "Couldn't find [$needle] anywhere!\n";
    print "<br>";
    }
}
[download]

Results in Perl yelling at you for using \i:

S:\Steve\Dev\PerlMonks\P-2017-05-31@0243-RegEx-Case-Insensitive>perl r
+egex0a.pl
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\i <-- HERE 1\-2\ Steps\i/ at regex0a.pl line 12.
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\i1\-2\ Steps\i <-- HERE / at regex0a.pl line 12.
<br>Couldn't find [1-2 Steps] anywhere!
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\i <-- HERE 5\-7\ Steps\i/ at regex0a.pl line 12.
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\i5\-7\ Steps\i <-- HERE / at regex0a.pl line 12.
<br><br>Couldn't find [5-7 Steps] anywhere!
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\i <-- HERE 8\-10\ Steps\i/ at regex0a.pl line 12.
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\i8\-10\ Steps\i <-- HERE / at regex0a.pl line 12.
<br><br>Couldn't find [8-10 Steps] anywhere!
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\i <-- HERE catch\i/ at regex0a.pl line 12.
Unrecognized escape \i passed through in regex; marked by <-- HERE in 
+m/\icatch\i <-- HERE / at regex0a.pl line 12.
<br><br>Couldn't find [catch] anywhere!
<br>
S:\Steve\Dev\PerlMonks\P-2017-05-31@0243-RegEx-Case-Insensitive>
[download]

Two ways to fix this.

Two key changes:

my $needle_regex = quotemeta $needle;
if ($haystack =~ /$needle_regex/i) {
[download]

New code:

my @needles   = ("1-2 Steps", "5-7 Steps", "8-10 Steps", "catch");
my @haystacks = ("move 1-2 steps", "move 8-10 steps to hoist", "catch 
+the ball");

for my $needle (@needles) {
    my $found;
    my $needle_regex = quotemeta $needle;

    for my $haystack (@haystacks) {
        if ($haystack =~ /$needle_regex/i) {
            print "<br>";
            print "Found [$needle] in [$haystack]\n";
            print "</br>";
            $found++;
        }
    }

    if (!$found) {
        print "<br>";
        print "Couldn't find [$needle] anywhere!\n";
        print "<br>";
    }
}
[download]

Or, in keeping with the approach you originally took, only one change needed:

if ($haystack =~ /\Q$needle\E/i) {
[download]

Resulting in:

my @needles   = ("1-2 Steps", "5-7 Steps", "8-10 Steps", "catch");
my @haystacks = ("move 1-2 steps", "move 8-10 steps to hoist", "catch 
+the ball");

for my $needle (@needles) {
    my $found;

    for my $haystack (@haystacks) {
        if ($haystack =~ /\Q$needle\E/i) {
            print "<br>";
            print "Found [$needle] in [$haystack]\n";
            print "</br>";
            $found++;
        }
    }

    if (!$found) {
        print "<br>";
        print "Couldn't find [$needle] anywhere!\n";
        print "<br>";
    }
}
[download]

If you're looking for in-line control of case insensitivity, use  (?i) to turn it on;  (?-i) turns it off. See  (?imsx-imsx) in Extended Patterns in perlre.

c:\@Work\Perl\monks>perl -wMstrict -le
"my @needles   = ('1-2 Steps', '5-7 Steps', '8-10 Steps', 'cAtCh', '*+
+??er',);
 my @haystacks = (
   'move 1-2 steps', 'move 8-10 steps to hoist', 'catch the ball', 'du
+mb *+??ER',
   );
 ;;
 for my $needle (@needles) {
   my $found;
   for my $haystack (@haystacks) {
     if ($haystack =~ /(?i)\Q$needle\E/) {
       print qq{Found [$needle] in [$haystack]};
       ++$found;
       }
     }
   ;;
   if (!$found) {
     print qq{Could not find [$needle] anywhere!};
     }
   }
"
Found [1-2 Steps] in [move 1-2 steps]
Could not find [5-7 Steps] anywhere!
Found [8-10 Steps] in [move 8-10 steps to hoist]
Found [cAtCh] in [catch the ball]
Found [*+??er] in [dumb *+??ER]
[download]