reading body of email not working

Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

Dear Monks, I am trying to read my emails with Perl, using the following code:

use strict;
use warnings;

# required modules
use Net::IMAP::Simple;
use Email::Simple;
use IO::Socket::SSL;

# fill in your details here
my $username = 'xxxxx';
my $password = 'yyyy';
my $mailhost = 'pop.gmail.com';

# Connect
my $imap = Net::IMAP::Simple->new(
    $mailhost,
    port    => 993,
    use_ssl => 1,
) || die "Unable to connect to IMAP: $Net::IMAP::Simple::errstr\n";

# Log in
if ( !$imap->login( $username, $password ) ) {
    print STDERR "Login failed: " . $imap->errstr . "\n";
    exit(64);
}
# Look in the the INBOX
my $nm = $imap->select('INBOX');

# How many messages are there?
my ($unseen, $recent, $num_messages) = $imap->status();
print "unseen: $unseen, recent: $recent, total: $num_messages\n\n";


## Iterate through unseen messages
for ( my $i = 1 ; $i <= $nm ; $i++ ) {
    if ( $imap->seen($i) ) {
        next;
    }
    else {
    my $es = Email::Simple->new( join '', @{ $imap->top($i) } );


    printf( "[%03d] %s\n\t%s\n", $i, $es->header('From'), $es->header(
+'Subject'), $es->body ('Body'));
    }
}
# Disconnect
$imap->quit;

exit;
[download]

The code works fine, but I cannot see the body of the email (I can see the "From", "Subject" etc), probably the $es->body ('Body') is wrong, but I do not know what the correct would be, can you help me?

Comment on reading body of email not working Select or Download Code

Replies are listed 'Best First'.
Re: reading body of email not working -- get not top by Discipulus (Canon) on Jun 01, 2017 at 08:05 UTC
Hello again Anonymous Monk nice to meet another italian (probably ;=) I'm not so skilled in email reading, but me too I receive an empty body. I modified the program a bit with `use Data::Dump` and then `printf( "[%03d] %s\n", $i, $es->header('From'), $es->header('Subject') +); print "BODY[".$es->body."]\n\n"; dd $es; # got: BODY[] bless({ body => \"",` [download] UPDATE: ahah the problem is the `top` you must use `get` `my $es = Email::Simple->new( join '', @{ $imap->get($i) } ); # here!` [download] L* There are no rules, there are no thumbs.. Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.	[reply] [d/l] [select]
Re^2: reading body of email not working -- get not top by Anonymous Monk on Jun 01, 2017 at 08:41 UTC
Thank you very much ! (I am Greek, but close enough :D :D )	[reply]
Re: reading body of email not working by hippo (Archbishop) on Jun 01, 2017 at 08:07 UTC
The documentation of the top() method (which you are using to create `$es`) in Net::IMAP::Simple is quite clear. It doesn't return the body. Consider using the get() method or similar instead.	[reply] [d/l]
Re: reading body of email not working by Eily (Monsignor) on Jun 01, 2017 at 07:44 UTC
The format in your printf only contains three variables but your mail body is the fourth. Just add another %s to the format.	[reply]
Re^2: reading body of email not working by Anonymous Monk on Jun 01, 2017 at 08:01 UTC
Hm, good observation... I changed it but this line: `printf( "[%04d] %s\n\t%s\n", $i, $es->header('From'), $es->header('Sub +ject'), $es->body);` [download] again does not show the body of the email...	[reply] [d/l]
Re^3: reading body of email not working by Eily (Monsignor) on Jun 01, 2017 at 08:12 UTC
Still only three variables (except the number will be printed with 4 digits instead of three). Your next post is a little more helpful though. The documentation for top() in Net::IMAP::Simple states that it returns the lines of the header so it doesn't seem to be the correct way to access the body of the mail.	[reply]
Re^3: reading body of email not working by Anonymous Monk on Jun 01, 2017 at 08:02 UTC
As a matter of fact, this command: `print $es->body;` [download] does not print anything...	[reply] [d/l]
Re: reading body of email not working by Discipulus (Canon) on Jun 01, 2017 at 07:09 UTC
Hello, I think it is just: `$email->body;` and not `$email->body('Body');` as for the synopsis of the module. L* There are no rules, there are no thumbs.. Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.	[reply] [d/l] [select]
Re^2: reading body of email not working by Anonymous Monk on Jun 01, 2017 at 07:30 UTC
Same, I only get: `[608] www-data@gpcr.biocomp.unibo.it (www-data) F4JWB3 \| Signal peptide` [download] so no body still :(	[reply] [d/l]