You could use zip from List::MoreUtils to mesh the arrays into a hash, then sort the keys by the values:

use strict; use warnings; use feature 'say';
use Data::Dumper;

use List::MoreUtils 'zip';

my @x = qw/d b c e a f/;
my @y = qw/4 6 5 2 9 1/;

my %h = zip @x, @y;
my @z = ( sort { $h{ $b } <=> $h{ $a } } keys %h )[0..3];

say Dumper \@z;

__END__
[download]

$VAR1 = [
          'a',
          'b',
          'c',
          'd'
        ];
[download]

Hope this helps!

Hi 1nickt,

Thank you for your prompt reply. The code works nicely and my problem is solved.

With kind regards,

Hello supriyoch_2008,

Another possible way, using Slices.

I would have the same approach as 1nickt did already. Initially create a hash from two arrays and then simply sort the values in descending order.

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my %hash;
my @x = qw/d b c e a f/;
my @y = qw/4 6 5 2 9 1/;

@hash{@x} = @y;

print Dumper \%hash;

my @sorted = (sort {$hash{$b} <=> $hash{$a}} keys %hash) [0 .. 3];

print Dumper \@sorted;

__END__

$ perl test.pl
$VAR1 = {
          'f' => '1',
          'c' => '5',
          'a' => '9',
          'd' => '4',
          'b' => '6',
          'e' => '2'
        };
$VAR1 = [
          'a',
          'b',
          'c',
          'd'
        ];
[download]

Hope this helps.

Hi thanos1983,

Thank you for your help. The code given by you has solved my problem.

With deep regards,

Hello again supriyoch_2008,

Thanks for the feedback, just to add something here. All answers of the monks are working, try them, or at least read and understand them for educations purposes.

Also fellow monk tybalt89 just posted a nice approach Re: How can I get the four highest valued letters in an array?, using grep.

If I was use you I would create subroutines to test all solution through Benchmark and decide the best approach based on speed. Or decide which one is easier for your to understand and maintain in future.

Keep up the good work and happy coding. :D

Seeking for Perl wisdom...on the process of learning...not there...yet!

And now for something completely different...

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1191833

use strict;
use warnings;

my @x=qw/d b c e a f/;
my @y=qw/4 6 5 2 9 1/;

my @answer;
@answer[@y] = @x;
@answer = (grep defined, reverse @answer)[0..3];

print "@answer\n";
[download]

In descending_order, you print your values.

Maybe you want to just return the values there instead to further operate on them?

Hi Corion,

Thank you for your comment.

With regards,

I dont know if is or not considered a best practice but it works..

A semplified example will show you what I mean

perl -e "@orig=qw(A p B e C r D l);@orig=sort{ord($a)<=>ord($b)}@orig;
+$#orig=3;print join ' ',@orig"

A B C D
[download]

L*

Hi Discipulus,

Thank you for your suggestions.

With regards,

To keep it simple:

 @letters = ("d","b","c","e","a","f");
@getallen = (4,6,5,2,9,1);
$teller = 0;
foreach $letter(@letters){
    $hash{$letter}=$getallen[$teller];
    $teller++;    }
@keyz = keys(%hash);
@sorted= reverse sort(@keyz);
@highest = @sorted[0..3];
foreach(@highest){
    print "$_:";
    print $hash{$_};
    print "\n";}
[download]

Simply garbage.



The way forward always starts with a minimal test.

May be