#!/usr/bin/perl
use strict;
use feature qw{ say };
use warnings;

use JSON::PP;

my $json = "{'k1':'v1','k2':'v2'}";
decode_json($json);
[download]

Error:

unexpected end of string while parsing JSON string, at character offse
+t 2 (before "k1':'v1','k2':'v2'}")
[download]

JSON::XS gives even more informative message:

'"' expected, at character offset 1 (before "'k1':'v1','k2':'v2'}")
[download]

JSON understands double quotes only:

'{"k1":"v1","k2":"v2"}'
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

> Your string isn't a valid JSON.

Indeed! I tested in the FF console, and JSON.parse(str) rejects single quotes.

Replacing with double quotes is fixing the problem.

see also http://stackoverflow.com/questions/36038454/parsing-string-as-json-with-single-quotes

Cheers Rolf
_{(addicted to the Perl Programming Language and ☆☆☆☆ :)
Je suis Charlie!}

PS: reply composed before choroba updated the root cause (single quotes)

Maybe try using JSON::PP instead. Almost identical interface, but it's installed by default with Perl since 5.13.9.

See Yes, even you can use CPAN. Also JSON::PP which is pure perl and has no no-core dependencies.

Following up on what tobyink and 1nickt said, in a recent distribution I wrote, I let the compiler decide whether to use JSON (XS) or JSON::PP which is already in the core. If JSON is not installed, it'll automatically fall back to the core JSON::PP.

BEGIN {

    # look for JSON::XS, and if not available, fall
    # back to JSON::PP to avoid requiring non-core modules

    my $json_ok = eval {
        require JSON::XS;
        JSON::XS->import;
        1;
    };
    if (! $json_ok){
        require JSON::PP;
        JSON::PP->import;
    }
}
[download]

Isn't that what JSON does? See also JSON::MaybeXS .

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

But that's the point. The OP says that they cannot install JSON "due to limitation" (whatever that may mean). This is therefore a nice means for them to choose between the modules which actually do the work without having to install the non-core JSON module.

I thought so, but I'm sure when I tested it on a box without JSON::XS it failed. I could have been imagining things at the time after a long day of work, so I'll re-test this today.

"...alternative way to parse json without json module?"

merlyn tried it some years ago at JSON parser as a single Perl Regex. But i guess your JSON needs to be valid however.

Minor update: Fixed link.

Hi, Sorry for the given JSON(it was only for example). I also checked and tried to use JSON::PP which comes as default. But my current perl does not have this also. I have installed perl 5.22.0-r0 via OPKG. It shows very basic module. I am not doing this on our general linux(eg ubuntu). I am doing it on board which has linux OS. So, I used OPKG to install perl which is supported by linux on that board. So, I am searching for function or something that I can use in my CGI script to decode json. Thanks.

You can install JSON::PP by copying the files onto your machine.

Also, consider maybe JSON::Tiny, which can also be installed by copying.

"...I am searching for function..."

Yes, sure. I got it. Here it is (as i already mentioned):

#!/usr/bin/env perl

use strict;
use warnings;
use Data::Dumper qw(Dumper);

my $FROM_JSON = qr{

(?&VALUE) (?{ $_ = $^R->[1] })

(?(DEFINE)

(?<OBJECT>
 (?{ [$^R, {}] })
  \{
    (?: (?&KV) # [[$^R, {}], $k, $v]
     (?{ # warn Dumper { obj1 => $^R };
      [$^R->[0][0], {$^R->[1] => $^R->[2]}] })
      (?: , (?&KV) # [[$^R, {...}], $k, $v]
       (?{ # warn Dumper { obj2 => $^R };
          [$^R->[0][0], {%{$^R->[0][1]}, $^R->[1] => $^R->[2]}] })
      )*
    )?
  \}
)

(?<KV>
  (?&STRING) # [$^R, "string"]
  : (?&VALUE) # [[$^R, "string"], $value]
 (?{ # warn Dumper { kv => $^R };
     [$^R->[0][0], $^R->[0][1], $^R->[1]] })
)

(?<ARRAY>
 (?{ [$^R, []] })
  \[
    (?: (?&VALUE) (?{ [$^R->[0][0], [$^R->[1]]] })
      (?: , (?&VALUE) (?{ # warn Dumper { atwo => $^R };
       [$^R->[0][0], [@{$^R->[0][1]}, $^R->[1]]] })
      )*
    )?
  \]
)

(?<VALUE>
  \s*
  (
      (?&STRING)
    |
      (?&NUMBER)
    |
      (?&OBJECT)
    |
      (?&ARRAY)
    |
    true (?{ [$^R, 1] })
  |
    false (?{ [$^R, 0] })
  |
    null (?{ [$^R, undef] })
  )
  \s*
)

(?<STRING>
  (
    "
    (?:
      [^\\"]+
    |
      \\ ["\\/&#660;bfnrt]
#    |
#      \\ u [0-9a-fA-f]{4}
    )*
    "
  )

 (?{ [$^R, eval $^N] })
)

(?<NUMBER>
  (
    -?
    (?: 0 | [1-9]\d* )
    (?: \. \d+ )?
    (?: [eE] [-+]? \d+ )?
  )

  (?{ [$^R, eval $^N] })
)

) }xms;

sub from_json {
    local $_ = shift;
    local $^R;
    eval { m{\A$FROM_JSON\z}; } and return $_;
    die $@ if $@;
    return 'no match';
}


my $json = q({"k1":"v1","k2":"v2"});

print Dumper from_json($json);

__END__

karls-mac-mini:Desktop karl$ ./godfather.pl
$VAR1 = {
          'k2' => 'v2',
          'k1' => 'v1'
        };
[download]

Update: Oops!. Better with Data::Dumper

Thank merlyn for the regex.

Regards, Karl

«The Crux of the Biscuit is the Apostrophe»

Furthermore I consider that Donald Trump must be impeached as soon as possible

If you are using opkg to install packages you are not using "it on a board which has linux OS".

You seem to be using OpenWrt which is a different OS.

It may help to indicate which version you are using and what device you use.