Fun with Prototypes

Can you tell me:

How does this get parsed? (e.g. try adding parentheses to show precedence)
Given that the body of each of the four subs is { print Dumper(\@_) }, what is the output?

$_ = "#x";
my @a = qw/b c/;

foo /#(\w+)/, @a;
bar /#(\w+)/, @a;
quz /#(\w+)/, @a;
baz /#(\w+)/, @a;
[download]

Hint:

Okay, it's a trick question, I'm trying to make a point about Prototypes - I didn't give enough information for you to answer it, and if you were already thinking of an answer, sorry but you're probably wrong. So here's the missing information:

sub foo       { print Dumper(\@_) }
sub bar ()    { print Dumper(\@_) }
sub quz ($)   { print Dumper(\@_) }
sub baz ($\@) { print Dumper(\@_) }
[download]

Solution:

1. Parsing according to perl -MO=Deparse,-p (with some edits for clarity):

foo( /#(\w+)/, @a );
(  bar() /  # division; "#(\w+)/, @a;" is a comment
   quz( /#(\w+)/ )
), @a;  # void context
&baz( scalar(/#(\w+)/), \@a );
[download]

2. Output (again slightly edited, and without warnings):

$VAR1 = ['x','b','c'];   # sub foo
$VAR1 = [];              # sub bar ()
$VAR1 = [1];             # sub quz ($)
$VAR1 = [1, ['b','c']];  # sub baz ($\@)
[download]

See Far More than Everything You've Ever Wanted to Know about Prototypes in Perl -- by Tom Christiansen. The code was inspired by merlyn's great node On Parsing Perl.

Comment on Fun with Prototypes Select or Download Code

Replies are listed 'Best First'.
Re: Fun with Prototypes by LanX (Saint) on Jul 19, 2017 at 21:37 UTC
I think you shouldn't hide the "hint", or at least rename it to "missing info". Hint implies that it's already solvable. Cheers Rolf _{(addicted to the Perl Programming Language and ☆☆☆☆ :) Je suis Charlie!}	[reply]
Re^2: Fun with Prototypes by haukex (Archbishop) on Jul 23, 2017 at 20:35 UTC
Thanks for the comments, and I did think about it - but I think I want to keep the "trick question" aspect of the node for now ;-) Also thank you for your other replies, that's certainly getting pretty tricky with the parsing!	[reply]
Re: Fun with Prototypes by LanX (Saint) on Jul 19, 2017 at 21:45 UTC
More fun for you: ;) Some people want debug functions to disappear without footprint in production. Like with Smart::Comments but without source filter. Try to find a way where changing the prototype of a function `&dmp` will turn the call to a no op. Your `bar /#(\w+)/, @a;` is already quite close, but it's still involving a division. :) Cheers Rolf _{(addicted to the Perl Programming Language and ☆☆☆☆ :) Je suis Charlie!}	[reply] [d/l] [select]
Re^2: Fun with Prototypes by tobyink (Canon) on Jul 22, 2017 at 11:22 UTC
Isn't this sufficiently clear? `use constant DEBUG => 0; use Data::Dumper; # ... warn Dumper($myvar) if DEBUG;` [download] Or PerX::Assert.	[reply] [d/l]
Re^3: Fun with Prototypes by LanX (Saint) on Jul 22, 2017 at 22:28 UTC
> Isn't this sufficiently clear? > ... > `warn Dumper($myvar) if DEBUG;` clear but unnecessarily verbose. Cheers Rolf _{(addicted to the Perl Programming Language and ☆☆☆☆ :) Je suis Charlie!}	[reply] [d/l]
Re^2: Fun with Prototypes by LanX (Saint) on Jul 20, 2017 at 12:49 UTC
an example avoiding a sub-call, unfortunately the division in void context is not optimized away. <Reveal this spoiler or all in this thread> and the warning will create runtime overhead, too :/ update But I think a little overhead is acceptable when debugging. another edge case are empty arrays causing a division by zero... update: fixed minor bug Cheers Rolf _{(addicted to the Perl Programming Language and ☆☆☆☆ :) Je suis Charlie!}	[reply] [d/l] [select]
Re: Fun with Prototypes by Laurent_R (Canon) on Jul 19, 2017 at 14:16 UTC
I don't quite understand what you're after, but you can check this module: B::Deparse Update: Sorry haukex, the spoilers did not work when I first tried to click on them. Now that I can see them, I understand your point.	[reply]

update

update: