"... parsing an ini..."

In a hurry: Config::IniFiles...? Regards, Karl

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1196747

use strict;
use warnings;
use Data::Dump 'pp';

while(<DATA>)
  {
  /RepeatingGroup\s*=\s*
    (?<GroupID>\b\S+\b)\s*
    (?=.*(?<Flatten>\bFlatten\b))?
    (?=.*(?<Direction>\b(in|out)\b))?
    /x or next;
  print;
  pp \%+;
  }

__DATA__
RepeatingGroup = Waiver, Flatten, out
RepeatingGroup = Waiver, out
RepeatingGroup = Waiver, out, Flatten
RepeatingGroup = Waiver , in
RepeatingGroup = Waiver , Flatten
[download]

In Perl, I would use a module like Config::Tiny to parse the .ini file. This would handle different [Sections] in the .ini file. However it appears that you only have the "root", section (no name) to deal with.

I would consider a sequence of regular expressions instead of one complex regex. Something perhaps like below. In Perl sometimes it is actually faster execution wise to run a couple of regex'es on the same variable rather one complex one. In this case, as I understand it, your INI file which will only be parsed once at the start of your program (meaning that performance really doesn't matter that much for this task). I recommend forgetting this lookahead stuff, it is not needed here. Go with simple multiple statements.

#!/usr/bin/perl
use strict;
use warnings;

my @example = (
            'RepeatingGroup = Waiver, Flatten, out',
            'RepeatingGroup = Waiver, out',
            'RepeatingGroup = Waiver, out, Flatten',
            'RepeatingGroup = Waiver , in',
            'RepeatingGroup = Waiver , Flatten', 
            );            

foreach my $example (@example)
{
   $example =~ s/^RepeatingGroup =\s*//;
   print "This is what .ini parser says: $example\n";
   
   my ($name,$direction,$flatten) = parseRepeatingGroup($example);
   print "  name      = $name\n".
         "  direction = $direction\n",
         "  flatten   = $flatten\n";
}

sub parseRepeatingGroup
{
   my $value_text = shift;
   
   my ($name,$rest) = $value_text =~ /^\s*(\S+)(.*)+/;
   my $direction = ($value_text =~ /\bin\b/i) ? 'in' : 'out';
   my $flatten   = ($value_text =~ /\bFLATTEN\b/i)? 1: 0;

   return ($name,$direction,$flatten);
}

__END__
This is what .ini parser says: Waiver, Flatten, out
  name      = Waiver,
  direction = out
  flatten   = 1
This is what .ini parser says: Waiver, out
  name      = Waiver,
  direction = out
  flatten   = 0
This is what .ini parser says: Waiver, out, Flatten
  name      = Waiver,
  direction = out
  flatten   = 1
This is what .ini parser says: Waiver , in
  name      = Waiver
  direction = in
  flatten   = 0
This is what .ini parser says: Waiver , Flatten
  name      = Waiver
  direction = out
  flatten   = 1
[download]

In C, I would use a very different approach. I don't see the need for regex in the C code. There are other ways of doing this, but this is not a C or C++ forum.

(?=.*(?<Flatten>\bFlatten\b))?
[download]

(?:\\s*,\\s*(?P<Flatten>\\bFlatten\\b))?
[download]

Yep, Data::Dumper also works, it's just not as "cool".

Here's an alternate that only allows Flatten, in, or out (but note that multiples are allowed)

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1196747

use strict;
use warnings;
use Data::Dumper;

while(<DATA>)
  {
  /RepeatingGroup\s*=\s*
    (?<GroupID>\b\w+\b)
    (\s*,\s*
      ((?<Flatten>\bFlatten\b)|(?<Direction>\b(in|out)\b))
    )*
    \s*$/x or next;
  print $_, Dumper \%+;
  }

__DATA__
RepeatingGroup = Waiver, Flatten, out
RepeatingGroup = Waiver, out
RepeatingGroup = Waiver, out, Flatten
RepeatingGroup = Waiver , in
RepeatingGroup = Waiver , Flatten
RepeatingGroup = LEI, out, Flatten
[download]

*cool* is in the eye of the beholder, worthy monk:

$ corelist Data::Dumper

Data for 2017-01-14
Data::Dumper was first released with perl 5.005

$ corelist Data::Dump

Data for 2017-01-14
Data::Dump was not in CORE (or so I think)
[download]

To some, "cool" is working without non-core modules, not necessarily what's newer or more fashionable. I'm not saying that Data::Dump is bad, I'm just pointing out that Data::Dumper is available with almost any Perl 5 install.

use warnings;
use strict;
use Data::Dump;

my $re = qr{ \A \s*
    RepeatingGroup \s* = \s*
    (?<GroupID> \b[^\ \t]+\b ) \s*
    ( , \s*
        (?: (?<Flatten> \bFlatten\b )
          | (?<Direction> \b(?:in|out)\b ) )
    \s* ){1,2}
    \z }msx;

dd $_, /$re/ ? \%+ : "FAIL" while <DATA>;

__DATA__
RepeatingGroup = Waiver, Flatten, out
RepeatingGroup = Waiver, out
RepeatingGroup = Waiver, out, Flatten
RepeatingGroup = Waiver , in
RepeatingGroup = Waiver , Flatten
[download]

But putting comma in the exclusion class prevents getting "out" and Flatten is captured but "out" remains uncaptured

BTW, you HAVE TO, HAVE TO, HAVE TO, HAVE TO, HAVE TO, HAVE TO put your regex in code blocks or PM eats the character class.