array push fails

rsFalse has asked for the wisdom of the Perl Monks concerning the following question:

Hello,

I've tried to use push() on array, but program tells me an error.

#!/usr/bin/perl

use warnings;
use strict;

my @numbers = 6 .. 9;
my @odd = ( 1, 5, 3 );
my @even = ( 4, 10 );

$\ = $/; $, = ' ';

map { print( ( $_ % 2 ? @odd : @even ), "+$_" ) } @numbers;
map { push( ( $_ % 2 ? @odd : @even ), "+$_" ) } @numbers;
[download]

OUTPUT:

4 10 +6
1 5 3 +7
4 10 +8
1 5 3 +9
Not an ARRAY reference at ./push_fail.pl line 13.
[download]

How can I correctly push using "?:" operator?

Comment on array push fails Select or Download Code

Replies are listed 'Best First'.
Re: array push fails by NetWallah (Canon) on Aug 14, 2017 at 18:26 UTC
`map { push( @{$_ % 2 ? \@odd : \@even }, "+$_" ) } @numbers;` [download] On my (perl 5.24) system, your original code says: `Experimental push on scalar is now forbidden at pf.pl line 13, near "" ++$_" ) "` [download] Update: BTW - "map" is not the best choice for this code, because you are throwing away the result of the map. Preferred, and more concise: `push( @{$_ % 2 ? \@odd : \@even }, "+$_" ) for @numbers;` [download] Then there is room for optimization: `my @evenodd = (\@even, \@odd); push( @{$evenodd[$_ % 2]}, "+$_" ) for @numbers;` [download] All power corrupts, but we need electricity.	[reply] [d/l] [select]
Re: array push fails by Cristoforo (Curate) on Aug 14, 2017 at 18:39 UTC
You can push to the odd/even array by looking at this example from perlfaq4. https://metacpan.org/pod/distribution/perlfaq/lib/perlfaq4.pod#How-do-I-compute-the-difference-of-two-arrays?-How-do-I-compute-the-intersection-of-two-arrays?	[reply]
Re^2: array push fails by rsFalse (Chaplain) on Aug 14, 2017 at 19:06 UTC
Thank you guys for answers and links! ;)	[reply]
Re: array push fails by Mr. Muskrat (Canon) on Aug 14, 2017 at 18:37 UTC
NetWallah++ for beating me to the answer. :) This has been asked before... See also: Using ternary operator as lvalue in push.	[reply]