It's theoretically possible, but "it's stupid to use a variable as a variable name".

Usually, a hash serves well in these situations:

use warnings;
use strict;

my $counter = 0;
my %hash;
while (<>) {
  $counter++;
  $hash{"bin_$counter"} = $_; # or whatever
}

use Data::Dumper;
print Dumper(\%hash);
[download]

use strict;
use warnings;

my $counter=0;
my @bin;
while( my $line = <> )
{
  $counter++;
  $bin[$counter] = $line;
}
[download]

see perldata#List-value-constructors for details on arrays (numbers as indices) and hashes (strings as keys)

and please always use

use strict;
use warnings;
[download]

Anonymous one: Variations on this approach are

c:\@Work\Perl\monks\Anonymous Monk\1199083>perl -wMstrict -MData::Dump
+ -le
"my @bin;
 ;;
 while(my $line = <>) {
   push @bin, $line;
   }
 ;;
 dd \@bin;
"  junk_1.txt
["line uno\n", "line two\n", "line 3\n"]

c:\@Work\Perl\monks\Anonymous Monk\1199083>perl -wMstrict -MData::Dump
+ -le
"my @bin = <>;
 ;;
 dd \@bin;
"  junk_1.txt
["line uno\n", "line two\n", "line 3\n"]
[download]

where junk_1.txt contains

line uno
line two
line 3
[download]

Both these variations relieve you of the need to maintain the  $counter counter (assuming it's initialized to 0).

---

Give a man a fish:  <%-{-{-{-<

Greetings,

I don't actually get, why you want this. If I read you right, first you are saying you want the counter as a name.

Then at the end you are saying, you want it as a value, and your code shows you add it as a value.

So it looks to me line you have to make up your mind about what it is you want. Nevertheless, this solution gives you both the names and the values:

my $counter=0;
my %names;
while(<>)
{
  $counter++;
  $names{"bin_".$counter} = "bin_".$counter;
}

use Data::Dumper qw(Dumper);
print Dumper \%names;
[download]

So maybe that's a starting point.

Cheers, Sören

Hello Anonymous Monk,

I think/assume you want to know the line number as you read the file. If so no need to use counters etc, Perl has got your back. Use the perlvar/Variables related to filehandles/$.. Then combine it with a hash as the fellow monks has provided you with several examples.

Sample of code:

#!/usr/bin/perl
use strict;
use warnings;
use feature qw(say);

while (<>) {
    chomp;
    say $. . "\t" . $_;
}

__END__

$ perl test.pl test_1.txt
1    Line 1
2    Line 2
3    Line 3
[download]

Hope this helps, BR.