G'day MurciaNew,

Here's a technique that will read your data in blocks, by localising a temporary value for the input record separator ($/).

#!/usr/bin/env perl

use strict;
use warnings;

my %data;

{
    local $/ = ":\n";
    my $block_re = qr{\A(.*)^(.*?):?\Z}ms;
    my $key;

    while (<DATA>) {
        my ($data, $label) = /$block_re/;
        $data{$key} = $data if defined $key;
        $data{$key} .= $label if eof DATA;
        $key = $label; 
    }
} 

use Data::Dump;
dd \%data;

__DATA__
AAA:
123
456
789
BBB:
qwe
rty
uio
CCC:
asd
fgh
jkl
[download]

Notes:

• There's nothing particularly special about the regex ($block_re); see perlre if you need to.
• The first block read only has a label. That's dealt with by the 'if defined $key' condition.
• The last block read only has data. That's dealt with by the 'if eof DATA' condition.
• You'll need to replace DATA with $fh (or similar). See open for more on that.
• I've used Data::Dump just to show the results of the data extraction: that's not part of the technique.
• The code assumes your example data is representative. If it's not, the general technique should still be sound, but you may need to make some modifications.

Here's the output from that code:

{
  AAA => "123\n456\n789\n",
  BBB => "qwe\nrty\nuio\n",
  CCC => "asd\nfgh\njkl\n",
}
[download]